build-support/disabled/rime-luna-pinyin-bootstrap/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgname=rime-luna-pinyin-bootstrap
_pkgname=${pkgname%-*}
pkgver='0.0.0.20210303'
conflicts=(rime-luna-pinyin)
provides=("rime-luna-pinyin=$pkgver")
_commit=f1268e192ca88b9526467ce04ac3e47c837891ad
pkgrel='1'
pkgdesc="Luna pinyin for rime"
arch=('x86_64')
url="https://github.com/rime/rime-luna-pinyin"
license=('LGPL')
# dependency for reverse lookup
#depends=('rime-stroke')
makedepends=('librime' 'rime-prelude' 'rime-essay')
source=("https://github.com/rime/rime-luna-pinyin/archive/$_commit/rime-luna-pinyin-$_commit.tar.gz")
sha512sums=('5a4f91f04f807ba84650a52acf8f634382c32eb978e8895f97b05594ea90cf6771386bb80cda1b694905c50d64cf8b4e8514abb762c4d18035b73c67148339f9')

prepare() {
  cd $_pkgname-$_commit
  # Link essentials
  for _f in $(pacman -Qql rime-prelude rime-essay | grep -v "/$"); do ln -sf $_f; done
}

build(){
  cd $_pkgname-$_commit
  for _s in $(ls *.schema.yaml); do rime_deployer --compile $_s; done
}

package() {
  cd $_pkgname-$_commit
  find . -type l -delete
  rm build/*.txt
  install -Dm644 *.yaml -t "$pkgdir"/usr/share/rime-data/
  install -Dm644 build/* -t "$pkgdir"/usr/share/rime-data/build/
}