1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
|
unit gui_trackbar;
{$mode objfpc}{$H+}
{
TODO:
* Tick line orientation (top, bottom, left or right)
* Slide the slider with the mouse button down (like a scrollbar)
* Slider button style (rectangle, pointer, double pointer)
* Tick captions
}
interface
uses
Classes,
SysUtils,
gfxbase,
fpgfx,
gfx_widget;
type
TTrackBarChange = procedure(Sender: TObject; APosition: integer) of object;
TfpgTrackBar = class(TfpgWidget)
private
FBackgroundColor: TfpgColor;
FMax: integer;
FMin: integer;
FOnChange: TTrackBarChange;
FOrientation: TOrientation;
FPosition: integer;
FSliderSize: integer;
procedure DoChange;
procedure SetBackgroundColor(const AValue: TfpgColor);
procedure SetMax(const AValue: integer);
procedure SetMin(const AValue: integer);
procedure SetPosition(const AValue: integer);
procedure SetSliderSize(const AValue: integer);
procedure FixMinMaxOrder;
procedure FixPositionLimits;
procedure DrawSlider(p: integer);
protected
procedure HandlePaint; override;
procedure HandleLMouseUp(x, y: integer; shiftstate: TShiftState); override;
procedure HandleKeyPress(var keycode: word; var shiftstate: TShiftState; var consumed: boolean); override;
public
constructor Create(AOwner: TComponent); override;
published
property BackgroundColor: TfpgColor read FBackgroundColor write SetBackgroundColor;
property Min: integer read FMin write SetMin default 0;
property Max: integer read FMax write SetMax default 10;
property Position: integer read FPosition write SetPosition default 0;
property SliderSize: integer read FSliderSize write SetSliderSize default 11;
property Orientation: TOrientation read FOrientation write FOrientation default orHorizontal;
property OnChange: TTrackBarChange read FOnChange write FOnChange;
end;
implementation
{ TfpgTrackBar }
procedure TfpgTrackBar.DoChange;
begin
if Assigned(FOnChange) then
FOnChange(self, FPosition);
end;
procedure TfpgTrackBar.SetBackgroundColor(const AValue: TfpgColor);
begin
if FBackgroundColor = AValue then
Exit; //==>
FBackgroundColor := AValue;
RePaint;
end;
procedure TfpgTrackBar.SetMax(const AValue: integer);
begin
if FMax = AValue then
Exit; //==>
FMax := AValue;
RePaint;
end;
procedure TfpgTrackBar.SetMin(const AValue: integer);
begin
if FMin = AValue then
Exit; //==>
FMin := AValue;
RePaint;
end;
procedure TfpgTrackBar.SetPosition(const AValue: integer);
begin
if FPosition = AValue then
Exit; //==>
FPosition := AValue;
RePaint;
// OnChange only fired on keyboard or mouse input.
end;
procedure TfpgTrackBar.SetSliderSize(const AValue: integer);
begin
if FSliderSize = AValue then
Exit; //==>
if AValue > 11 then
begin
FSliderSize := AValue;
RePaint;
end;
end;
procedure TfpgTrackBar.FixMinMaxOrder;
var
lmin: integer;
lmax: integer;
begin
if FMax < FMin then
begin
lmin := FMax; // change order
lmax := FMin;
FMax := lmax; // reassign values
FMin := lmin;
end;
end;
procedure TfpgTrackBar.FixPositionLimits;
begin
if FPosition < FMin then
FPosition := FMin;
if FPosition > FMax then
FPosition := FMax;
end;
procedure TfpgTrackBar.DrawSlider(p: integer);
var
h: integer;
begin
if Orientation = orHorizontal then
begin
h := Height div 2 - 1;
Canvas.SetColor(clHilite1);
Canvas.DrawLine(p - FSliderSize div 2,5, p + FSliderSize div 2, 5);
Canvas.DrawLine(p - FSliderSize div 2,5, p - FSliderSize div 2, h - FSliderSize div 2);
Canvas.DrawLine(p - FSliderSize div 2, h - FSliderSize div 2, p, h + FSliderSize div 2);
Canvas.SetColor(clHilite2);
Canvas.DrawLine(p - FSliderSize div 2 + 1,6, p + FSliderSize div 2 - 1, 6);
Canvas.DrawLine(p - FSliderSize div 2 + 1,6, p - FSliderSize div 2 + 1, h - FSliderSize div 2);
Canvas.DrawLine(p - FSliderSize div 2 + 1, h - FSliderSize div 2, p, h + FSliderSize div 2 - 1);
Canvas.SetColor(clShadow2);
Canvas.DrawLine(p + FSliderSize div 2, 6, p + FSliderSize div 2, h - FSliderSize div 2);
Canvas.DrawLine(p + FSliderSize div 2, h - FSliderSize div 2, p + 1, h + FSliderSize div 2 - 1);
Canvas.SetColor(clShadow1);
Canvas.DrawLine(p + FSliderSize div 2 - 1, 7, p + FSliderSize div 2 - 1, h - FSliderSize div 2);
Canvas.DrawLine(p + FSliderSize div 2 - 1, h - FSliderSize div 2, p + 1, h + FSliderSize div 2 - 2);
end
else
begin
h := Width div 2 - 1;
Canvas.SetColor(clHilite1);
Canvas.DrawLine(5,p - FSliderSize div 2, 5, p + FSliderSize div 2);
Canvas.DrawLine(5,p - FSliderSize div 2, h - FSliderSize div 2, p - FSliderSize div 2);
Canvas.DrawLine( h - FSliderSize div 2, p - FSliderSize div 2, h + FSliderSize div 2,p);
Canvas.SetColor(clHilite2);
Canvas.DrawLine(6,p - FSliderSize div 2 + 1, 6, p + FSliderSize div 2 - 1);
Canvas.DrawLine(6,p - FSliderSize div 2 + 1, h - FSliderSize div 2, p - FSliderSize div 2 + 1);
Canvas.DrawLine(h - FSliderSize div 2,p - FSliderSize div 2 + 1, h + FSliderSize div 2 - 1,p);
Canvas.SetColor(clShadow2);
Canvas.DrawLine( 6,p + FSliderSize div 2, h - FSliderSize div 2, p + FSliderSize div 2);
Canvas.DrawLine( h - FSliderSize div 2,p + FSliderSize div 2, h + FSliderSize div 2 - 1, p + 1);
Canvas.SetColor(clShadow1);
Canvas.DrawLine( 7, p + FSliderSize div 2 - 1, h - FSliderSize div 2,p + FSliderSize div 2 - 1);
Canvas.DrawLine( h - FSliderSize div 2, p + FSliderSize div 2 - 1, h + FSliderSize div 2 - 2, p + 1);
end;
end;
procedure TfpgTrackBar.HandlePaint;
var
r: TRect;
linepos: double;
drawwidth: integer;
i: integer;
begin
Canvas.BeginDraw;
// inherited HandlePaint;
r := Rect(0, 0, Width-1, Height-1);
Canvas.Clear(FBackgroundColor);
if FFocused then
Canvas.SetColor(clWidgetFrame)
else
Canvas.SetColor(clInactiveWgFrame);
Canvas.DrawRectangle(r);
FixMinMaxOrder;
FixPositionLimits;
if Orientation = orHorizontal then
begin
drawwidth := Width - 5 - FSliderSize;
linepos := FMax - FMin;
if linepos <> 0 then
begin
linepos := drawwidth / linepos;
Canvas.SetColor(clWidgetFrame);
for i := 0 to (FMax - FMin) do
Canvas.DrawLine(round(2 + (FSliderSize div 2) + (linepos * i)), Height div 2 + FSliderSize * 2, round(2 + FSliderSize div 2 + linepos * i), Height - 5);
DrawSlider(round(2 + FSliderSize div 2 + linepos * position));
end;
end
else
begin
drawwidth := Height - 5 - FSliderSize;
linepos := FMax - FMin;
if linepos <> 0 then
begin
linepos := drawwidth / linepos;
Canvas.SetColor(clWidgetFrame);
for i := 0 to (FMax - FMin) do
Canvas.DrawLine(Width div 2 + FSliderSize * 2, round(2 + (FSliderSize div 2) + (linepos * i)), Width - 5, round(2 + FSliderSize div 2 + linepos * i));
DrawSlider(round(2 + FSliderSize div 2 + linepos * position));
end;
end; { if/else }
Canvas.EndDraw;
end;
procedure TfpgTrackBar.HandleLMouseUp(x, y: integer; shiftstate: TShiftState);
var
p: integer;
linepos: double;
drawwidth: integer;
OldPos: integer;
begin
OldPos := Position;
FixMinMaxOrder;
linepos := FMax - FMin;
if Orientation = orHorizontal then
begin
drawwidth := Width - 5 - FSliderSize;
linepos := drawwidth / linepos;
FPosition := round((x - 2 - FSliderSize div 2) / linepos) + FMin;
end
else
begin
drawwidth := Height - 5 - FSliderSize;
linepos := drawwidth / linepos;
FPosition := round((y - 2 - FSliderSize div 2) / linepos) + FMin;
end;
RePaint;
if Position <> OldPos then
DoChange;
// inherited HandleLMouseUp(x, y, shiftstate);
end;
procedure TfpgTrackBar.HandleKeyPress(var keycode: word;
var shiftstate: TShiftState; var consumed: boolean);
var
OldPos: integer;
begin
consumed := True;
OldPos := FPosition;
if Orientation = orHorizontal then
begin
case keycode of
keyLeft: Position := Position - 1;
keyRight: Position := Position + 1;
keyPageUp: Position := FMin;
keyPageDown: Position := FMax;
else
consumed := False;
end;
end
else
begin
case keycode of
keyUp: Position := Position - 1;
keyDown: Position := Position + 1;
keyPageUp: Position := FMin;
keyPageDown: Position := FMax;
else
consumed := False;
end;
end; { if/else }
inherited HandleKeyPress(keycode, shiftstate, consumed);
if OldPos <> Position then
DoChange;
end;
constructor TfpgTrackBar.Create(AOwner: TComponent);
begin
inherited Create(AOwner);
FBackgroundColor := clWindowBackground;
FFocusable := True;
FMin := 0;
FMax := 10;
FPosition := 0;
FSliderSize := 11;
FOrientation := orHorizontal;
FOnChange := nil;
end;
end.
|
