1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
|
{
fpGUI - Free Pascal GUI Toolkit
Copyright (C) 2006 - 2008 See the file AUTHORS.txt, included in this
distribution, for details of the copyright.
See the file COPYING.modifiedLGPL, included in this distribution,
for details about redistributing fpGUI.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
Description:
Defines a basic Label control. Also known as a Caption component.
}
unit gui_label;
{$mode objfpc}{$H+}
interface
uses
Classes,
SysUtils,
gfxbase,
fpgfx,
gfx_UTF8utils,
gfx_widget;
type
TfpgCustomLabel = class(TfpgWidget)
private
FAutoSize: boolean;
FAlignment: TAlignment;
FLayout: TLayout;
FWrapText: boolean;
FLineSpace: integer;
procedure SetWrapText(const AValue: boolean);
procedure SetAlignment(const AValue: TAlignment);
procedure SetLayout(const AValue: TLayout);
function GetFontDesc: string;
procedure SetAutoSize(const AValue: boolean);
procedure SetFontDesc(const AValue: string);
procedure SetText(const AValue: string);
procedure ResizeLabel;
protected
FText: string;
FFont: TfpgFont;
FTextHeight: integer;
procedure HandlePaint; override;
property WrapText: boolean read FWrapText write SetWrapText default False;
property Alignment: TAlignment read FAlignment write SetAlignment default taLeftJustify;
property AutoSize: boolean read FAutoSize write SetAutoSize default False;
property Layout: TLayout read FLayout write SetLayout default tlTop;
property FontDesc: string read GetFontDesc write SetFontDesc;
property Text: string read FText write SetText;
property LineSpace: integer read FLineSpace write FLineSpace default 2;
public
constructor Create(AOwner: TComponent); override;
destructor Destroy; override;
property Font: TfpgFont read FFont;
property TextHeight: integer read FTextHeight;
end;
TfpgLabel = class(TfpgCustomLabel)
published
property Alignment;
property AutoSize;
property BackgroundColor;
property FontDesc;
property Layout;
property LineSpace;
property Text;
property TextColor;
property Width;
property WrapText;
property OnClick;
property OnDoubleClick;
property OnMouseDown;
property OnMouseEnter;
property OnMouseExit;
property OnMouseMove;
property OnMouseUp;
end;
// A convenience function to create a TfpgLabel instance
function CreateLabel(AOwner: TComponent; x, y: TfpgCoord; AText: string; w: TfpgCoord= 0; h: TfpgCoord= 0;
HAlign: TAlignment= taLeftJustify; VAlign: TLayout= tlTop; ALineSpace: integer= 2): TfpgLabel; overload;
implementation
function CreateLabel(AOwner: TComponent; x, y: TfpgCoord; AText: string; w: TfpgCoord; h: TfpgCoord;
HAlign: TAlignment; VAlign: TLayout; ALineSpace: integer): TfpgLabel;
begin
Result := TfpgLabel.Create(AOwner);
Result.Left := x;
Result.Top := y;
Result.Text := AText;
Result.LineSpace := ALineSpace;
if w = 0 then
begin
Result.Width := Result.Font.TextWidth(Result.Text);
Result.FAutoSize := True;
end
else
Result.Width := w;
if h < Result.Font.Height then
Result.Height:= Result.Font.Height
else
Result.Height:= h;
Result.Alignment:= HAlign;
Result.Layout:= VAlign;
end;
{ TfpgCustomLabel }
procedure TfpgCustomLabel.SetWrapText(const AValue: boolean);
begin
if FWrapText <> AValue then
begin
FWrapText := AValue;
ResizeLabel;
end;
end;
procedure TfpgCustomLabel.SetAlignment(const AValue: TAlignment);
begin
if FAlignment <> AValue then
begin
FAlignment := AValue;
ResizeLabel;
end;
end;
procedure TfpgCustomLabel.SetLayout(const AValue: TLayout);
begin
if FLayout <> AValue then
begin
FLayout := AValue;
ResizeLabel;
end;
end;
function TfpgCustomLabel.GetFontDesc: string;
begin
Result := FFont.FontDesc;
end;
procedure TfpgCustomLabel.SetAutoSize(const AValue: boolean);
begin
if FAutoSize <> AValue then
begin
FAutoSize := AValue;
ResizeLabel;
end;
end;
procedure TfpgCustomLabel.SetFontDesc(const AValue: string);
begin
FFont.Free;
FFont := fpgGetFont(AValue);
ResizeLabel;
end;
procedure TfpgCustomLabel.SetText(const AValue: string);
begin
if FText <> AValue then
begin
FText := AValue;
ResizeLabel;
end;
end;
procedure TfpgCustomLabel.ResizeLabel;
begin
if FAutoSize and not FWrapText then
Width:= FFont.TextWidth(FText);
UpdateWindowPosition;
RePaint;
end;
constructor TfpgCustomLabel.Create(AOwner: TComponent);
begin
inherited Create(AOwner);
FText := 'Label';
FFont := fpgGetFont('#Label1');
FHeight := FFont.Height;
FWidth := 80;
FTextColor := Parent.TextColor;
FBackgroundColor := Parent.BackgroundColor;
FAutoSize := False;
FLayout := tlTop;
FAlignment := taLeftJustify;
FWrapText := False;
FLineSpace := 2;
end;
destructor TfpgCustomLabel.Destroy;
begin
FText := '';
FFont.Free;
inherited Destroy;
end;
procedure TfpgCustomLabel.HandlePaint;
var
i: integer;
r: TfpgRect;
lTxtFlags: TFTextFlags;
begin
inherited HandlePaint;
Canvas.ClearClipRect;
r.SetRect(0, 0, Width, Height);
Canvas.Clear(FBackgroundColor);
Canvas.SetFont(Font);
if Enabled then
Canvas.SetTextColor(FTextColor)
else
Canvas.SetTextColor(clShadow1);
lTxtFlags:= [];
if Enabled then
Include(lTxtFlags, txtEnabled);
if FWrapText then
Include(lTxtFlags, txtWrap);
case FAlignment of
taLeftJustify:
Include(lTxtFlags, txtLeft);
taRightJustify:
Include(lTxtFlags, txtRight);
taCenter:
Include(lTxtFlags, txtHCenter);
end;
case FLayout of
tlTop:
Include(lTxtFlags, txtTop);
tlBottom:
Include(lTxtFlags, txtBottom);
tlCenter:
Include(lTxtFlags, txtVCenter);
end;
FTextHeight := Canvas.DrawText(0, 0, Width, Height, FText, lTxtFlags);
end;
end.
|
