1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
|
{
Some handly UTF8 function copied from the Lazarus LCL. Comes from the LCLProc
unit.Surely we can move this into FPC?
}
unit gfx_UTF8utils;
{$mode objfpc}{$H+}
interface
uses
Classes, SysUtils;
function UTF8CharacterLength(p: PChar): integer;
function UTF8CharStart(UTF8Str: PChar; Len, Index: integer): PChar;
function UTF8Copy(const s: string; StartCharIndex, CharCount: integer): string;
function UTF8CStringToUTF8String(SourceStart: PChar; SourceLen: SizeInt): string;
function UTF8Length(const s: string): integer;
function UTF8Length(p: PChar; ByteCount: integer): integer;
function UTF8Pos(const SearchForText, SearchInText: string): integer;
procedure UTF8Delete(var S: string; Index, Size: integer);
procedure UTF8Insert(const Source: string; var S: string; Index: integer);
implementation
// returns the character index, where the SearchForText starts in SearchInText
function UTF8Pos(const SearchForText, SearchInText: string): integer;
var
p: LongInt;
begin
p := System.Pos(SearchForText, SearchInText);
if p > 0 then
Result := UTF8Length(PChar(SearchInText), p-1) + 1
else
Result := 0;
end;
// returns substring
function UTF8Copy(const s: string; StartCharIndex, CharCount: integer): string;
var
StartBytePos: PChar;
EndBytePos: PChar;
MaxBytes: PtrInt;
begin
StartBytePos := UTF8CharStart(PChar(s),length(s),StartCharIndex-1);
if StartBytePos = nil then
Result := ''
else
begin
MaxBytes := PtrInt(PChar(s)+length(s)-StartBytePos);
EndBytePos := UTF8CharStart(StartBytePos,MaxBytes,CharCount);
if EndBytePos = nil then
Result := copy(s,StartBytePos-PChar(s)+1,MaxBytes)
else
Result := copy(s,StartBytePos-PChar(s)+1,EndBytePos-StartBytePos);
end;
end;
function UTF8CStringToUTF8String (SourceStart: PChar; SourceLen: SizeInt): string;
var
Source: PChar;
Dest: PChar;
SourceEnd: PChar;
CharLen: integer;
SourceCopied: PChar;
// Copies from SourceStart till Source to Dest and updates Dest
procedure CopyPart; inline;
var
CopyLength: SizeInt;
begin
CopyLength := Source - SourceCopied;
if CopyLength=0 then exit;
move(SourceCopied^ , Dest^, CopyLength);
SourceCopied:=Source;
inc(Dest, CopyLength);
end;
begin
SetLength(Result, SourceLen);
if SourceLen=0 then
Exit; //==>
SourceCopied:=SourceStart;
Source:=SourceStart;
Dest:=PChar(Result);
SourceEnd := Source + SourceLen;
while Source<SourceEnd do
begin
CharLen := UTF8CharacterLength(Source);
if (CharLen=1) and (Source^='\') then
begin
CopyPart;
inc(Source);
if Source^ in ['t', 'n', '"', '\'] then
begin
case Source^ of
't' : Dest^ := #9;
'"' : Dest^ := '"';
'\' : Dest^ := '\';
'n' :
// fpc 2.1.1 stores string constants as array of char so maybe this
// will work for without ifdef (once available in 2.0.x too):
// move(lineending, dest^, sizeof(LineEnding));
{$IFDEF WINDOWS}
begin
move(lineending[1], dest^, length(LineEnding));
inc(dest^, length(LineEnding)-1);
end;
{$ELSE}
Dest^ := LineEnding;
{$ENDIF}
end;
inc(Source);
inc(Dest);
end;
SourceCopied := Source;
end
else
Inc(Source, CharLen);
end;
CopyPart;
SetLength(Result, Dest - PChar(Result));
end;
function UTF8Length(const s: string): integer;
begin
Result := UTF8Length(PChar(s),length(s));
end;
function UTF8Length(p: PChar; ByteCount: integer): integer;
var
CharLen: LongInt;
begin
Result := 0;
while (ByteCount > 0) do
begin
inc(Result);
CharLen := UTF8CharacterLength(p);
inc(p, CharLen);
dec(ByteCount, CharLen);
end;
end;
function UTF8CharStart(UTF8Str: PChar; Len, Index: integer): PChar;
var
CharLen: LongInt;
begin
Result := UTF8Str;
if Result <> nil then
begin
while (Index > 0) and (Len > 0) do
begin
CharLen := UTF8CharacterLength(Result);
dec(Len, CharLen);
dec(Index);
inc(Result, CharLen);
end;
if (Index > 0) or (Len < 0) then
Result := nil;
end;
end;
function UTF8CharacterLength(p: PChar): integer;
begin
if p <> nil then
begin
if ord(p^) < %11000000 then
begin
// regular single byte character (#0 is a character, this is pascal ;)
Result:=1;
end
else if ((ord(p^) and %11100000) = %11000000) then
begin
// could be 2 byte character
if (ord(p[1]) and %11000000) = %10000000 then
Result := 2
else
Result := 1;
end
else if ((ord(p^) and %11110000) = %11100000) then
begin
// could be 3 byte character
if ((ord(p[1]) and %11000000) = %10000000)
and ((ord(p[2]) and %11000000) = %10000000) then
Result:=3
else
Result:=1;
end
else if ((ord(p^) and %11111000) = %11110000) then
begin
// could be 4 byte character
if ((ord(p[1]) and %11000000) = %10000000)
and ((ord(p[2]) and %11000000) = %10000000)
and ((ord(p[3]) and %11000000) = %10000000) then
Result:=4
else
Result:=1;
end
else
Result:=1;
end
else
Result:=0;
end;
procedure UTF8Insert(const Source: string; var S: string; Index: integer);
var
b: string;
e: string;
begin
if UTF8Length(Source) = 0 then
Exit; //==>
b := UTF8Copy(S, 1, Index-1); // beginning string
e := UTF8Copy(S, Index, UTF8Length(S)-Index+1); // ending string
S := b + Source + e;
end;
procedure UTF8Delete(var S: string; Index, Size: integer);
var
ls: integer;
b: string;
e: string;
begin
ls := UTF8Length(S);
if (Index > ls) or (Index <= 0) or (Size <= 0) then
Exit; //==>
b := UTF8Copy(S, 1, Index-1); // beginning string
e := UTF8Copy(S, Index+Size, UTF8Length(S)-(Index+Size-1)); // ending string
S := b + e;
end;
end.
|
