blob: 523949f75f584e163638b1e58ba50d632d67399b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Sébastien Luttringer
pkgname=virtualbox-ext-oracle
pkgver=6.1.18
pkgrel=1
pkgdesc='Oracle VM VirtualBox Extension Pack'
arch=('any')
url='http://www.virtualbox.org/'
license=('custom:PUEL')
options=('!strip')
install=virtualbox-ext-oracle.install
source=("http://download.virtualbox.org/virtualbox/$pkgver/Oracle_VM_VirtualBox_Extension_Pack-$pkgver.vbox-extpack")
noextract=("Oracle_VM_VirtualBox_Extension_Pack-$pkgver.vbox-extpack")
sha512sums=('3686b1c5dbdc5b28c172b4885c30ca9a444bc10dc7984df14a17e1dcc571456b06e80ad38e1409de8692c483c56f397162a53bd3dc6956d9ca91875fda0bda4e')
prepare() {
# shrink uneeded cpuarch
[[ -d shrunk ]] || mkdir shrunk
tar xfC "Oracle_VM_VirtualBox_Extension_Pack-$pkgver.vbox-extpack" shrunk
rm -r shrunk/{darwin*,solaris*,win*}
tar -c --gzip --file shrunk.vbox-extpack -C shrunk .
}
package() {
depends=('virtualbox')
optdepends=('rdesktop: client to connect vm via RDP')
install -Dm 644 shrunk.vbox-extpack \
"$pkgdir/usr/share/virtualbox/extensions/Oracle_VM_VirtualBox_Extension_Pack-$pkgver.vbox-extpack"
install -Dm 644 shrunk/ExtPack-license.txt \
"$pkgdir/usr/share/licenses/$pkgname/PUEL"
}
# vim:set ts=2 sw=2 et:
|
