blob: b6262662fd003bee36acd0d368b7d77123b4f9af (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Sébastien Luttringer
pkgname=virtualbox-ext-oracle
pkgver=6.1.6
pkgrel=1
pkgdesc='Oracle VM VirtualBox Extension Pack'
arch=('any')
url='http://www.virtualbox.org/'
license=('custom:PUEL')
options=('!strip')
install=virtualbox-ext-oracle.install
source=("http://download.virtualbox.org/virtualbox/$pkgver/Oracle_VM_VirtualBox_Extension_Pack-$pkgver.vbox-extpack")
noextract=("Oracle_VM_VirtualBox_Extension_Pack-$pkgver.vbox-extpack")
sha512sums=('938564a68e7b18a83022329217c2304470a3682ccd5a837be3caa1b802d3c7bed450428c1d3176fac571eb8a53dca2405ca53853163ad613ef056bc3b3beef68')
prepare() {
# shrink uneeded cpuarch
[[ -d shrunk ]] || mkdir shrunk
tar xfC "Oracle_VM_VirtualBox_Extension_Pack-$pkgver.vbox-extpack" shrunk
rm -r shrunk/{darwin*,solaris*,win*}
tar -c --gzip --file shrunk.vbox-extpack -C shrunk .
}
package() {
depends=('virtualbox')
optdepends=('rdesktop: client to connect vm via RDP')
install -Dm 644 shrunk.vbox-extpack \
"$pkgdir/usr/share/virtualbox/extensions/Oracle_VM_VirtualBox_Extension_Pack-$pkgver.vbox-extpack"
install -Dm 644 shrunk/ExtPack-license.txt \
"$pkgdir/usr/share/licenses/$pkgname/PUEL"
}
# vim:set ts=2 sw=2 et:
|
