blob: 01be8321ce8f8db1aacc0f80de151e54255f28a0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Francois Boulogne <fboulogne at april dot org>
# Contributor: Jingbei Li <i@jingbei.li>
pkgbase=python-pywavelets
pkgname=(python-pywavelets python2-pywavelets)
_pkgname=pywt
pkgver=1.0.0
pkgrel=1
pkgdesc="Discrete Wavelet Transforms in Python"
arch=('x86_64' 'i686')
url="https://github.com/PyWavelets/pywt"
license=('MIT')
_deppy2=(
'python2>=2.7'
'python2<2.8'
)
_deppy=(
'python>=3.7'
'python<3.8'
)
_depends=(
'python-numpy')
_makedepends=(
'cython>=0.20.2'
'python-numpy'
'python-setuptools')
source=("$_pkgname-$pkgver.tar.gz::https://github.com/PyWavelets/pywt/archive/v$pkgver.tar.gz")
sha512sums=('ef2ba5394f06e2d38d4526aa292428b81f37f94e875dcae34cdf7846f3fa4e8f62cd0ff6dd465a63ee8280440c6774a45b4025787e8a5ab22c901c4848da21ff')
makedepends=(
"${_deppy[@]}"
"${_deppy2[@]}"
"${_makedepends[@]}"
"${_makedepends[@]/ython/ython2}"
"${_depends[@]}"
"${_depends[@]/python/python2}"
)
prepare() {
cd "$srcdir/"
cp -a "${_pkgname}-${pkgver}" "${_pkgname}-${pkgver}-py2"
cd "${_pkgname}-${pkgver}-py2"
sed -e "s|#![ ]*/usr/bin/python$|#!/usr/bin/python2|" \
-e "s|#![ ]*/usr/bin/env python$|#!/usr/bin/env python2|" \
-e "s|#![ ]*/bin/env python$|#!/usr/bin/env python2|" \
-i $(find . -name '*.py')
}
build() {
msg "Building Python 2"
cd "$srcdir/${_pkgname}-${pkgver}-py2"
python2 setup.py build
msg "Building Python 3"
cd "$srcdir/$_pkgname-$pkgver"
python setup.py build
}
package_python2-pywavelets(){
depends=(
"${_deppy2[@]}"
"${_depends[@]/python/python2}"
)
cd "$srcdir/$_pkgname-$pkgver-py2"
python2 setup.py install --root="$pkgdir/" --optimize=1
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
package_python-pywavelets(){
depends=(
"${_deppy[@]}"
"${_depends[@]}"
)
cd "$srcdir/$_pkgname-$pkgver"
python setup.py install --root="$pkgdir/" --optimize=1
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
# vim:ts=2:sw=2:et:
|
