perl-task-weaken/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor:Maxwell Pray a.k.a. Synthead <synthead@gmail.com>
# Contributor: AUR Perl <aurperl@juster.info>

pkgname=perl-task-weaken
_cpanname="Task-Weaken"
pkgver=1.04
pkgrel='3'
_distdir="${_cpanname}-${pkgver}"
pkgdesc="Ensure that a platform has weaken support"
arch=('any')
license=('PerlArtistic' 'GPL')
options=('!emptydirs')
depends=('perl>=5.5.0')
url="http://search.cpan.org/dist/$_cpanname"
source=("http://search.cpan.org/CPAN/authors/id/A/AD/ADAMK/${_distdir}.tar.gz")
sha512sums=('19749fada2b030a082d745abbc172125c3e195be5e1166ff02511fbf08aa8d37092cb0ea2cbf95452fef70f2e1cd0062d32f04d74aa52b30f6e85108f9ca80ff')

# Function to change to the working directory and set
# environment variables to override undesired options.
prepareEnvironment() {
	cd "${srcdir}/${_distdir}"
	export \
		PERL_MM_USE_DEFAULT=1 \
		PERL_AUTOINSTALL=--skipdeps \
		PERL_MM_OPT="INSTALLDIRS=vendor DESTDIR='$pkgdir'" \
		PERL_MB_OPT="--installdirs vendor --destdir '$pkgdir'" \
		MODULEBUILDRC=/dev/null
}

build() {
	prepareEnvironment
	/usr/bin/perl Makefile.PL
	make
}

check() {
	prepareEnvironment
	make test
}

package() {
	prepareEnvironment
	make install

	# Remove "perllocal.pod" and ".packlist".
	find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
}