perl-syntax-highlight-perl/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Ondrej Kucera <ondrej.kucera@centrum.cz>

pkgname=perl-syntax-highlight-perl
_perlmod=Syntax-Highlight-Perl
pkgver=1.0
pkgrel=10
_distdir="${_perlmod}-${pkgver}"
pkgdesc="Syntax-Highlight-Perl perl module (highlighting of Perl Syntactical Structures)"
arch=("any")
url="http://search.cpan.org/~johnsca/Syntax-Highlight-Perl/"
license=("GPL" "Artistic")
depends=('perl>=5.10.0')
source=(http://search.cpan.org/CPAN/authors/id/J/JO/JOHNSCA/${_distdir}.tar.gz)
sha512sums=('be1959493fb563137095e0b151fa56fe2192d1c4bf52e2ef32d6d2310b821a905e675a443e4cfb83da7d0dfa4cc267ac087d49d0ee807a07413cf839621ebe8b')
options=(!emptydirs)

build() {
  cd "${srcdir}/${_distdir}"

  # Install module in vendor directories.
  PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd "${srcdir}/${_distdir}"
  make test
}

package() {
  cd "${srcdir}/${_distdir}"
  make install DESTDIR="$pkgdir/"
}