blob: c35f979c837d3682cf306ad2cb425641f89e0109 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Maintainer: Erich Eckner <arch at eckner dot net>
pkgname='perl-mojolicious'
pkgver=8.0
pkgrel='3'
pkgdesc='Web development toolkit'
arch=('any')
license=('PerlArtistic' 'GPL')
options=('!emptydirs')
depends=(
'perl>=5.28'
'perl<5.29'
'perl-io-socket-ip>=0.37'
'perl-json-pp>=2.27103'
'perl-pod-simple>=3.09'
'perl-time-local>=1.2')
makedepends=(
'perl-extutils-makemaker')
checkdepends=(
'perl-ev>=4'
'perl-io-socket-socks>=0.64'
'perl-io-socket-ssl>=1.94'
'perl-role-tiny'
'perl-test-pod'
'perl-test-pod-coverage')
url='https://metacpan.org/release/Mojolicious'
_distdir="Mojolicious-${pkgver}"
source=("https://cpan.metacpan.org/authors/id/S/SR/SRI/${_distdir}.tar.gz")
sha512sums=('19126a663c52a45f1f32354567b97922453b542073308d2b7288f9deb568f598a2e7ed5b6db377bcb152437c942ed47f8fd805fae80d3f54db02d3a7160cc94e')
prepare() {
cd "$srcdir/$_distdir"
rm t/mojo/websocket_proxy_tls.t
rm t/mojo/tls.t
rm t/mojo/ioloop_tls.t
}
build() {
( export PERL_MM_USE_DEFAULT=1 PERL5LIB="" \
PERL_AUTOINSTALL=--skipdeps \
PERL_MM_OPT="INSTALLDIRS=vendor DESTDIR='$pkgdir'" \
PERL_MB_OPT="--installdirs vendor --destdir '$pkgdir'" \
MODULEBUILDRC=/dev/null
cd "$srcdir/$_distdir"
perl Makefile.PL
make
)
}
check() {
cd "$srcdir/$_distdir"
( export PERL_MM_USE_DEFAULT=1 PERL5LIB=""
export TEST_EV=1
export TEST_HYPNOTOAD=1
export TEST_IPV6=1
export TEST_MORBO=1
export TEST_ONLINE=1
export TEST_POD=1
export TEST_PREFORK=1
export TEST_SOCKS=1
export TEST_SUBPROCESS=1
export TEST_TLS=1
export TEST_UNIX=1
make test
)
}
package() {
cd "$srcdir/$_distdir"
make install
find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
}
# Local Variables:
# mode: shell-script
# sh-basic-offset: 2
# End:
# vim:set ts=2 sw=2 et:
|
