blob: 95fed537594a4e918f124d6ddd522d01fe8ab65d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Oliver Goethel <deezy>
# Contributor: eolianoe eolianoe <eolianoe [at] gmail [DoT] com>
# Contributor: George Eleftheriou <eleftg>
# Contributor: Mathias Anselmann <mathias.anselmann@gmail.com>
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: Michele Mocciola <mickele>
# Contributor: Simon Zilliken <simon____AT____zilliken____DOT____name>
pkgname=paraview
pkgver=5.3.0
pkgrel=1
pkgdesc='Parallel Visualization Application using VTK'
arch=('i686' 'x86_64')
url='http://www.paraview.org'
license=('custom')
depends=('qt5-tools' 'qt5-x11extras' 'qt5-xmlpatterns'
'openmpi' 'python2' 'ffmpeg' 'boost' 'glew'
'expat' 'freetype2' 'libjpeg' 'libxml2' 'libtheora' 'libpng' 'libtiff' 'zlib'
)
makedepends=('cmake' 'mesa' 'gcc-fortran')
optdepends=('python2-matplotlib: Needed to support equation rendering using MathText markup language'
'python2-numpy: Needed for using some filters such as "Python Calculator"')
source=("https://www.paraview.org/files/v${pkgver:0:3}/ParaView-v${pkgver}.tar.gz"
'paraview-desktop.patch'
'vtk_hdf5_internal.patch')
sha512sums=('3dc3c2a1c27a0f0dc82fc04ce84477a26aacb329d6ea42c276c4204e39d11bc78adbc1807e1e7168aade31aa48b6d628775841b8b94b5122084eac46e358a23f'
'5b9a29e0cb7c9a2ec60345bc81115323885e2613bd18fb208803393ad1ef968ef03dd7ea3e04e97dcfdb101dbc13ef03560fd1a0fd6be325c66b4475c00efc19'
'b65286279175a6203a43027043802a09c06827034a7361ad9ea12f63bdd226d33e3b585c61ecf9fc8d411c841a9999758705c2c29c6eab29554c3d150d5913d9')
prepare() {
cd "${srcdir}/ParaView-v${pkgver}"
patch -p1 -i ../paraview-desktop.patch
patch -p1 -i ../vtk_hdf5_internal.patch
rm -rf "${srcdir}/build"
mkdir -p "${srcdir}/build"
}
build() {
cd "${srcdir}/build"
# flags to enable system libs
# add PROTOBUF when https://gitlab.kitware.com/paraview/paraview/issues/13656 gets fixed
local VTK_USE_SYSTEM_LIB=""
for lib in EXPAT FREETYPE GLEW JPEG LIBXML2 OGGTHEORA PNG TIFF ZLIB; do
VTK_USE_SYSTEM_LIB+="-DVTK_USE_SYSTEM_${lib}:BOOL=ON "
done
cmake \
-DBUILD_SHARED_LIBS:BOOL=ON \
-DBUILD_TESTING:BOOL=OFF \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_C_COMPILER=mpicc \
-DCMAKE_CXX_COMPILER=mpicxx \
-DCMAKE_INSTALL_PREFIX:PATH=/usr \
-DCMAKE_VERBOSE_MAKEFILE:BOOL=OFF \
-DPARAVIEW_ENABLE_CGNS:BOOL=OFF \
-DPARAVIEW_ENABLE_FFMPEG:BOOL=ON \
-DPARAVIEW_ENABLE_PYTHON:BOOL=ON \
-DPARAVIEW_PYTHON_VERSION=2 \
-DPARAVIEW_QT_VERSION=5 \
-DPARAVIEW_USE_MPI:BOOL=ON \
-DPARAVIEW_USE_VISITBRIDGE:BOOL=ON \
-DVISIT_BUILD_READER_CGNS:BOOL=OFF \
-DVTK_PYTHON_VERSION=2 \
-DVTK_QT_VERSION=5 \
-DVTK_RENDERING_BACKEND:STRING=OpenGL2 \
-DVTK_SMP_IMPLEMENTATION_TYPE:STRING=OpenMP \
-DVTK_USE_SYSTEM_HDF5:BOOL=OFF \
${VTK_USE_SYSTEM_LIB} \
../ParaView-v${pkgver}
make
}
package() {
cd "${srcdir}/build"
make DESTDIR="${pkgdir}" install
#Install license
install -Dm644 "${srcdir}/ParaView-v${pkgver}/License_v1.2.txt" "${pkgdir}/usr/share/licenses/paraview/LICENSE"
}
|
