blob: 154835df366682fef4f1ec5e441cd0cacfaa7617 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Kyle Keen <keenerd@gmail.com>
pkgname=hyperrogue
pkgver=13.0c
pkgrel=1
pkgdesc="You are a lone outsider in a strange, non-Euclidean hyperbolic world. Optional music."
arch=('i686' 'pentium4' 'x86_64')
url="http://www.roguetemple.com/z/hyper.php"
license=('GPL2')
_pinned_dependencies=(
'gcc-libs=13.2.1'
'glibc>=2.31'
'libGL.so=1'
'libz.so=1'
'sdl12-compat=1.2.68'
'sdl_gfx=2.0.27'
)
depends=('sdl_ttf' 'sdl_mixer' 'mesa' 'ttf-dejavu' "${_pinned_dependencies[@]}")
makedepends=('glu')
source=("https://github.com/zenorogue/hyperrogue/archive/refs/tags/v${pkgver}.tar.gz")
sha512sums=('44494b32dbc25070ca3a7f85daf6dab237c4a65571ac08a192e870ddf855433672e05926f1df0726b6f602d380fb6f6b68a92884a30592c650266217e7ff492b')
prepare() {
cd "$srcdir/$pkgname-${pkgver}"
sed -i 's|TTF_OpenFont.*;|TTF_OpenFont("/usr/share/fonts/TTF/DejaVuSans-Bold.ttf", siz);|' basegraph.cpp
#sed -i 's|<SDL.h>|"SDL.h"|' /usr/include/SDL/SDL_gfxPrimitives.h # todo: confirm bug and open
sed -i 's|-c hyper.cpp|& -I/usr/include/SDL/|' Makefile # remove when above bug is fixed
sed -i 's|savepng.c|savepng.cpp|' Makefile
sed -i 's|-Werror||' Makefile
}
build() {
cd "$srcdir/$pkgname-${pkgver}"
make
}
package() {
cd "$srcdir/$pkgname-${pkgver}"
install -Dm755 hyperrogue "$pkgdir/usr/bin/hyperrogue"
}
|
