blob: 5a128affa0387f7f001afb47db54075a70ec0ad3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
|
# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Knut Ahlers <knut at ahlers dot me>
# Contributor: Det <nimetonmaili g-mail>
# Contributors: t3ddy, Lex Rivera aka x-demon, ruario
# Check for new Linux releases in: http://googlechromereleases.blogspot.com/search/label/Stable%20updates
# or use: $ curl -s https://dl.google.com/linux/chrome/rpm/stable/x86_64/repodata/other.xml.gz | gzip -df | awk -F\" '/pkgid/{ sub(".*-","",$4); print $4": "$10 }'
pkgname=google-chrome
pkgver=108.0.5359.124
pkgrel=24
pkgdesc="The popular and trusted web browser by Google (Stable Channel)"
arch=('x86_64')
url="https://www.google.com/chrome"
license=('custom:chrome')
_pinned_dependencies=(
'gcc-libs=12.2.1'
'glibc>=2.36'
'libasound.so=2'
'libatk-1.0.so=0'
'libatk-bridge-2.0.so=0'
'libatspi.so=0'
'libcairo.so=2'
'libcups=1:2.4.2'
'libdbus-1.so=3'
'libdrm=2.4.115'
'libexpat.so=1'
'libgio-2.0.so=0'
'libglib-2.0.so=0'
'libgobject-2.0.so=0'
'libpango-1.0.so=0'
'libx11=1.8.4'
'libxcb=1.15'
'libxcomposite=0.4.6'
'libxdamage=1.1.6'
'libxext=1.3.5'
'libxfixes=6.0.1'
'libxkbcommon.so=0'
'libxrandr=1.5.3'
'mesa=23.0.3'
'nspr=4.35'
'nss=3.89'
)
depends=(
'alsa-lib'
'gtk3'
'libcups'
'libxss'
'libxtst'
'nss'
'ttf-liberation'
'xdg-utils'
"${_pinned_dependencies[@]}"
)
optdepends=(
'pipewire: WebRTC desktop sharing under Wayland'
'kdialog: for file dialogs in KDE'
'gnome-keyring: for storing passwords in GNOME keyring'
'kwallet: for storing passwords in KWallet'
)
options=('!emptydirs' '!strip')
install=$pkgname.install
_channel=stable
source=("https://dl.google.com/linux/chrome/deb/pool/main/g/google-chrome-${_channel}/google-chrome-${_channel}_${pkgver}-1_amd64.deb"
'eula_text.html'
"google-chrome-$_channel.sh")
sha512sums=('800ffb452d703eb9867a1afb80acec88c4843e2fd888ea1788a104846af069f020195a60b720941cb788a02375521f27b6b9a16b98f354ab8dd2c866ad7c75af'
'a225555c06b7c32f9f2657004558e3f996c981481dbb0d3cd79b1d59fa3f05d591af88399422d3ab29d9446c103e98d567aeafe061d9550817ab6e7eb0498396'
'43519ec81d008c9f949ef52b98a718473913e888d99ff6598083e30cd1f07376b5e58a7639fd309ee19056c18eac58cbf6a31bec6bfd2509ebce9fa9d6919743')
package() {
echo " -> Extracting the data.tar.xz..."
bsdtar -xf data.tar.xz -C "$pkgdir/"
echo " -> Moving stuff in place..."
# Launcher
install -m755 google-chrome-$_channel.sh "$pkgdir"/usr/bin/google-chrome-$_channel
# Icons
for i in 16x16 24x24 32x32 48x48 64x64 128x128 256x256; do
install -Dm644 "$pkgdir"/opt/google/chrome/product_logo_${i/x*/}.png \
"$pkgdir"/usr/share/icons/hicolor/$i/apps/google-chrome.png
done
# License
install -Dm644 eula_text.html "$pkgdir"/usr/share/licenses/google-chrome/eula_text.html
install -Dm644 "$pkgdir"/opt/google/chrome/WidevineCdm/LICENSE \
"$pkgdir"/usr/share/licenses/google-chrome-$_channel/WidevineCdm-LICENSE.txt
echo " -> Fixing Chrome desktop entry..."
sed -i \
-e "/Exec=/i\StartupWMClass=Google-chrome" \
-e "s/x-scheme-handler\/ftp;\?//g" \
"$pkgdir"/usr/share/applications/google-chrome.desktop
echo " -> Removing Debian Cron job, duplicate product logos and menu directory..."
rm -r \
"$pkgdir"/etc/cron.daily/ \
"$pkgdir"/opt/google/chrome/cron/ \
"$pkgdir"/opt/google/chrome/product_logo_*.{png,xpm} \
"$pkgdir"/usr/share/menu/
}
|
