fpc-docs-svn/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: L <alaviss 0 at gmail dot com>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Valeriy Lyasotskiy <onestep@ukr.net>
# Contributor: Jan Willemson <janwil@hot.ee>
# Contributor: Hugo Ideler <hugoideler@dse.nl>
# Contributor: BlackIkeEagle <ike DOT devolder AT gmail DOT com>
# Original PKGBUILD: Andre Naumann <anaumann@SPARCed.org>
# See http://bbs.archlinux.org/viewtopic.php?t=9318&highlight=fpc

pkgname='fpc-docs-svn'
pkgver=2.6.0.r1099.99e25a3a
_pkgver="${pkgver%.r*}"
_commit="${pkgver##*.}"
pkgrel=1
arch=('any')
url='http://www.freepascal.org/'
license=('GPL' 'LGPL' 'custom')
pkgdesc='Documentation for the Free Pascal Compiler'
options=('!strip')
makedepends=('subversion'
  'texlive-core' 'texlive-htmlxml'
  'texlive-latexextra' 'ghostscript' 'fpc-src-svn' 'fpc-svn')
source=('git+https://gitlab.com/freepascal.org/fpc/documentation.git#commit='"${_commit}")
sha512sums=('SKIP')

pkgver() {
  cd "${srcdir}"/documentation
  last_version=$(
    git tag \
    | sed '
      s@^release_\([0-9_]\+\)$@\1@
      t
      d
    ' \
    | tr '_' '.' \
    | sort -V \
    | tail -n1
  )
  _commit=$(
    git rev-parse "${_commit}" \
    | cut -c1-8
  )
  revision=$(
    git rev-list --count "${_commit}" "^release_${last_version//./_}"
  )
   printf '%s.r%s.%s' \
    "${last_version}" \
    "${revision}" \
    "${_commit}"
}

build() {
  cd "${srcdir}"/documentation
  cp -r /usr/lib/fpc/src ../fpcsrc
  make -j1 FPCSRCDIR="${srcdir}"/fpcsrc html
}

package() {
  cd "${srcdir}"/documentation
  make PREFIX="${pkgdir}"/usr htmlinstall
}