blob: d6f1a88b3f1932ac944ca13bcb247bda1c7b8428 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Erich Eckner <arch at eckner dot net>
pkgname=fetchmail
pkgver=6.4.39
pkgrel=2
pkgdesc="A remote-mail retrieval utility"
arch=('i486' 'i686' 'pentium4' 'x86_64')
url="http://www.fetchmail.info"
license=('GPL')
_pinned_dependencies=(
'glibc>=2.31'
)
if [ "${OS}" = 'arch' ]; then
_pinned_dependencies+=(
'openssl=3.3.1'
)
else
_pinned_dependencies+=(
'libcrypto.so=3'
'libssl.so=3'
)
fi
depends=("${_pinned_dependencies[@]}")
makedepends=('python')
optdepends=('tk: for using fetchmailconf')
options=('!makeflags')
source=("https://sourceforge.net/projects/fetchmail/files/branch_${pkgver%.*}/${pkgname}-${pkgver}.tar.xz"
'disable-sslv3.patch' 'fetchmail.tmpfiles' 'fetchmail.sysusers' 'fetchmail.service')
sha512sums=('979721aead72c9b706f9c64a83cf78a91890f5a2dce235b3b4f0dbdb17e879eaef2fb9a08efb415cb288ebee07c915adc8025a6d2d11f532fb95a9e30f93f7f5'
'1425f3655c8fe7c6ca32b6fc876fd7f0ecfb24a86f63d9ee123fe710ebbdd8fbf5b5ef0f1831cd9702de56cc707a2361a427cf2ed840b63a39beda71a18dfba3'
'f6e3eb409a1d88bcfb02012491fdbbf859803dbee45998879525fd35a2377bae95504da8aafcb24bcc2e695e15c96f6ec6f7e6521d28012370a4ec5e2a25a351'
'c1169c54b70be53e3093d65a2d0f1e251fadf24a8008484583d79dd3cedea13782137c0db5f9052b2d02fdbd6bd0fdcb78c6403fe39926ac636b45a44d452b29'
'49c2843ddb06f587611f838bc9dab3fe04af991d70c27f8ffdd6351d8d6401683a356a03401e232a53e44ee43f6d85aa520f233f256974d07972913145fdf0f5')
prepare() {
cd ${pkgname}-${pkgver}
patch -Np1 -i ../disable-sslv3.patch
}
build() {
cd ${pkgname}-${pkgver}
./configure --prefix=/usr --with-ssl=/usr
make
}
package() {
install -D -m644 fetchmail.tmpfiles "${pkgdir}"/usr/lib/tmpfiles.d/fetchmail.conf
install -D -m644 fetchmail.sysusers "${pkgdir}"/usr/lib/sysusers.d/fetchmail.conf
install -D -m644 fetchmail.service "${pkgdir}"/usr/lib/systemd/system/fetchmail.service
cd ${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
install -d -o 90 -g nobody "${pkgdir}/var/lib/fetchmail"
}
|
