blob: cf917c7a05ad0869cee531f03003e5c288172e0e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Remi Gacogne <rgacogne at archlinux dot org>
pkgname=dnsdist
pkgver=1.8.0
_pkgver=${pkgver#*_}
_pkgver=${_pkgver//_/-}
pkgrel=12
pkgdesc='Highly DNS-, DoS- and abuse-aware loadbalancer'
arch=('x86_64')
url='https://dnsdist.org/'
license=('GPL2')
source=(https://downloads.powerdns.com/releases/${pkgname}-${_pkgver}.tar.bz2{,.asc}
sysusers.conf)
sha512sums=('426db3e83729bd2f8a8c8b1c02d719c6618acc0aec09d1f2670c159d441c1cad2fdc85c5ffe919e76d1b1e8e24198bf29133802cb857dfacde2dfed2532001f1'
'SKIP'
'd55ccd612cbe08b353815027d30a3b0f0ec7bf6b0d74a0a634939be53ce6e6b41d23e54c2328946f00738c03e9f306ce4f2dabe5e4b11d9fb28d0abf49917893')
validpgpkeys=('D6300CABCBF469BBE392E503A208ED4F8AF58446' # Remi Gacogne <remi.gacogne@powerdns.com>
'FBAE0323821C7706A5CA151BDCF513FA7EED19F3') # Peter van Dijk <peter.van.dijk@powerdns.com>
makedepends=('boost' 'systemd')
_pinned_dependencies=(
'fstrm=0.6.1'
'gcc-libs=13.2.1'
'glibc>=2.31'
'gnutls=3.8.2'
'libcap.so=2'
'libcdb.so=1'
'libcrypto.so=3'
'libedit.so=0'
'libnghttp2=1.58.0'
'libre2.so=11'
'libsodium.so=26'
'libssl.so=3'
'libsystemd.so=0'
'lmdb=0.9.30'
'luajit=2.1.1700008891'
'net-snmp=5.9.1'
)
depends=('h2o' 'openssl' 'tinycdb' "${_pinned_dependencies[@]}")
build() {
cd "${pkgname}-${_pkgver}"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--with-ebpf \
--with-gnutls \
--with-libsodium \
--with-libssl \
--with-nghttp2 \
--with-re2 \
--enable-dnstap \
--enable-dns-over-tls \
--enable-dns-over-https \
--enable-dnscrypt \
--enable-systemd \
--enable-lto=thin \
--enable-auto-var-init=zero \
--with-service-user=dnsdist \
--with-service-group=dnsdist
make
}
package() {
cd "${pkgname}-${_pkgver}"
make DESTDIR="${pkgdir}" install
cd "${srcdir}"
install -D -m644 sysusers.conf "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
}
|
