blob: 1cc0c3700fe8c4c71af5faeef3dfce9c4c23d51f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Remi Gacogne <rgacogne at archlinux dot org>
pkgname=dnsdist
pkgver=1.5.1
_pkgver=${pkgver#*_}
_pkgver=${_pkgver//_/-}
pkgrel=6
pkgdesc='Highly DNS-, DoS- and abuse-aware loadbalancer'
arch=('x86_64')
url='https://dnsdist.org/'
license=('GPL2')
source=(https://downloads.powerdns.com/releases/${pkgname}-${_pkgver}.tar.bz2{,.asc}
sysusers.conf)
sha512sums=('68fe5f55fd081ed80a620933af9f8310be0e21c86ba449a9c557975b5c83f4b64e3002e6032dc002582d081e70e1ec2ff080c5d8389fd46a9896bdafd5a41f9f'
'SKIP'
'd55ccd612cbe08b353815027d30a3b0f0ec7bf6b0d74a0a634939be53ce6e6b41d23e54c2328946f00738c03e9f306ce4f2dabe5e4b11d9fb28d0abf49917893')
validpgpkeys=('D6300CABCBF469BBE392E503A208ED4F8AF58446') # Remi Gacogne <remi.gacogne@powerdns.com>
makedepends=('boost' 'systemd')
_pinned_dependencies=(
'fstrm=0.6.0'
'gcc-libs=10.2.0'
'glibc>=2.31'
'gnutls=3.7.0'
'libcap.so=2'
'libcdb.so=1'
'libedit.so=0'
'libprotobuf.so=23'
'libsodium=1.0.18'
'libsystemd.so=0'
'lmdb=0.9.27'
'luajit=2.0.5'
'net-snmp=5.9'
'openssl=1.1.1.i'
're2=1:20210202'
)
depends=('h2o' "${_pinned_dependencies[@]}")
build() {
cd "${pkgname}-${_pkgver}"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--with-ebpf \
--with-protobuf \
--with-gnutls \
--with-libsodium \
--with-libssl \
--with-re2 \
--enable-dnstap \
--enable-dns-over-tls \
--enable-dns-over-https \
--enable-dnscrypt \
--enable-systemd
make
sed -i 's,CapabilityBoundingSet=CAP_NET_BIND_SERVICE CAP_SETGID CAP_SETUID,CapabilityBoundingSet=CAP_NET_BIND_SERVICE\nAmbientCapabilities=CAP_NET_BIND_SERVICE\nUser=dnsdist\nGroup=dnsdist,' dnsdist.service
}
package() {
cd "${pkgname}-${_pkgver}"
make DESTDIR="${pkgdir}" install
cd "${srcdir}"
install -D -m644 sysusers.conf "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
}
|
