blob: 628332c95d36d68ee2d673ae61139de7ed746f55 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Remi Gacogne <rgacogne at archlinux dot org>
pkgname=dnsdist
pkgver=1.6.0
_pkgver=${pkgver#*_}
_pkgver=${_pkgver//_/-}
pkgrel=2
pkgdesc='Highly DNS-, DoS- and abuse-aware loadbalancer'
arch=('x86_64')
url='https://dnsdist.org/'
license=('GPL2')
source=(https://downloads.powerdns.com/releases/${pkgname}-${_pkgver}.tar.bz2{,.asc}
sysusers.conf
gcc11.patch)
sha512sums=('f6a1676c431d5622af075bc184c9f82b4ea0bb40ec84797a8fe835804f91bc0a93a745495f193bb52f3a5204ec0e98ed41bc206c997d1f5b13e872bb31747b0f'
'SKIP'
'd55ccd612cbe08b353815027d30a3b0f0ec7bf6b0d74a0a634939be53ce6e6b41d23e54c2328946f00738c03e9f306ce4f2dabe5e4b11d9fb28d0abf49917893'
'97d12dd51ccb338fe0a907e684333936596501fdb316bdcddc7616ea723e6dfc9ca3ca3e479d17d14b317a0668658eac6fcb72e343919c0a2dea3ea99d34485d')
validpgpkeys=('D6300CABCBF469BBE392E503A208ED4F8AF58446') # Remi Gacogne <remi.gacogne@powerdns.com>
makedepends=('boost' 'systemd')
_pinned_dependencies=(
'fstrm=0.6.1'
'gcc-libs=11.1.0'
'glibc>=2.31'
'gnutls=3.7.1'
'libcap.so=2'
'libcdb.so=1'
'libedit.so=0'
'libsodium=1.0.18'
'libsystemd.so=0'
'lmdb=0.9.29'
'luajit=2.0.5'
'net-snmp=5.9'
'openssl=1.1.1.k'
're2=1:20210401'
)
depends=('h2o' "${_pinned_dependencies[@]}")
prepare() {
cd "${pkgname}-${_pkgver}"
patch -p1 -i "${srcdir}/gcc11.patch"
}
build() {
cd "${pkgname}-${_pkgver}"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--with-ebpf \
--with-protobuf \
--with-gnutls \
--with-libsodium \
--with-libssl \
--with-re2 \
--enable-dnstap \
--enable-dns-over-tls \
--enable-dns-over-https \
--enable-dnscrypt \
--enable-systemd
make
sed -i 's,CapabilityBoundingSet=CAP_NET_BIND_SERVICE CAP_SETGID CAP_SETUID,CapabilityBoundingSet=CAP_NET_BIND_SERVICE\nAmbientCapabilities=CAP_NET_BIND_SERVICE\nUser=dnsdist\nGroup=dnsdist,' dnsdist.service
}
package() {
cd "${pkgname}-${_pkgver}"
make DESTDIR="${pkgdir}" install
cd "${srcdir}"
install -D -m644 sysusers.conf "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
}
|
