blob: a6720acf726bf5a4b5008545c230c3cb794b5e82 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
# $Id$
# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: James Rayner <james@archlinux.org>
# Contributor: Partha Chowdhury <kira.laucas@gmail.com>
pkgname=conky-irc
pkgver=1.15.0
provides=("conky=${pkgver}")
conflicts=('conky')
_gitcommit=70d7d5c796e3e84e674705ffc6aaf7a0d6c5b109
pkgrel=2
pkgdesc='Lightweight system monitor for X - with irc-client enabled'
url='https://github.com/brndnmtthws/conky'
license=('BSD' 'GPL')
arch=('i686' 'pentium4' 'x86_64')
makedepends=('cmake' 'docbook2x' 'docbook-xsl' 'man-db' 'git' 'catch2' 'pandoc' 'python-yaml' 'python-jinja')
_pinned_dependencies=(
'gcc-libs=13.1.1'
'glibc>=2.31'
'imlib2=1.11.1'
'libcurl.so=4'
'libircclient.so=1'
'libncursesw.so=6'
'libpulse.so=0'
'libsystemd.so=0'
'libx11=1.8.6'
'libxdamage=1.1.6'
'libxext=1.3.5'
'libxfixes=6.0.1'
'libxft=2.3.8'
'libxinerama=1.1.5'
'libxml2.so=2'
'libXNVCtrl.so=0'
'lua=5.4.6'
'wireless_tools=30.pre9'
)
depends=('glib2' "${_pinned_dependencies[@]}")
optdepends=('mounted')
source=("git+https://github.com/brndnmtthws/conky.git#commit=${_gitcommit}?signed"
'MAX_SP.patch')
sha512sums=('SKIP'
'1ea39f88b5f2620fc0c4485cc16645dbad91f97be17b4b13a732205dde6265d621c7f2bc92be33b65f9db2815312beb42b516ddebbba90cfe947104e1a410a52')
validpgpkeys=(
'EB2E847572A71BE20F59AFBEB49ABB7270D9D4FD' # Brenden Matthews
)
pkgver() {
cd "${srcdir}/${pkgname%-irc}"
git describe --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${srcdir}/${pkgname%-irc}"
rm -r tests/catch2
ln -s /usr/include/catch2 tests
patch -p1 -i ../MAX_SP.patch
}
build() {
cd "${srcdir}/${pkgname%-irc}"
cmake \
-B build \
-D CMAKE_BUILD_TYPE=Release \
-D CMAKE_CXX_FLAGS="$CXXFLAGS -ffat-lto-objects" \
-D MAINTAINER_MODE=ON \
-D BUILD_DOCS=ON \
-D BUILD_EXTRAS=ON \
-D BUILD_WLAN=ON \
-D BUILD_XDBE=ON \
-D BUILD_XSHAPE=ON \
-D BUILD_IMLIB2=ON \
-D BUILD_CURL=ON \
-D BUILD_RSS=ON \
-D BUILD_NVIDIA=ON \
-D BUILD_WEATHER_METAR=ON \
-D BUILD_PULSEAUDIO=ON \
-D BUILD_JOURNAL=ON \
-D BUILD_IRC=ON \
-D CMAKE_INSTALL_PREFIX=/usr \
-Wno-dev \
-S .
make -C build
}
package() {
cd "${srcdir}/${pkgname%-irc}"
make -C build DESTDIR="${pkgdir}" install
install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
install -Dm 644 build/extras/vim/syntax/conkyrc.vim -t "${pkgdir}"/usr/share/vim/vimfiles/syntax
install -Dm 644 extras/vim/ftdetect/conkyrc.vim -t "${pkgdir}"/usr/share/vim/vimfiles/ftdetect
}
|
