wolkenwelten new

1 files changed, 46 insertions, 0 deletions

diff --git a/wolkenwelten-git/PKGBUILD b/wolkenwelten-git/PKGBUILD
new file mode 100644
index 000000000..db9f21681
--- /dev/null
+++ b/wolkenwelten-git/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer:  Erich Eckner <arch at eckner dot net>
+# Contributor: <reg-archlinux AT klein DOT tuxli DOT ch> 
+
+_pkgbase=WolkenWelten
+_pkgname=${_pkgbase,,}
+pkgname=${_pkgname}-git
+pkgver=r2022.bc445319
+pkgrel=1
+pkgdesc='Gamemix between Minecraft, Quake ]I[ and Emacs in C99'
+arch=('i686' 'pentium4' 'x86_64' 'aarch64')
+url="https://wolkenwelten.net/"
+license=('GNU')
+_pinned_dependencies=(
+  'glibc>=2.38'
+  'libGL.so=1'
+  'libvorbis.so=0'
+  'sdl2=2.28.3'
+)
+depends=('ffmpeg' 'sdl2' 'sdl2_mixer' "${_pinned_dependencies[@]}")
+makedepends=('clang' 'git' 'nasm')
+conflicts=("${_pkgname}")
+provides=("${_pkgname}")
+source=(${_pkgname}::"git+https://git.sr.ht/~melchizedek6809/${_pkgbase}")
+md5sums=('SKIP')
+
+pkgver() {
+  cd ${_pkgname}
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd ${_pkgname}
+  git submodule update --init --recursive
+}
+
+build() {
+  cd ${_pkgname}
+  make
+}
+
+package() {
+  cd ${_pkgname}
+  install -Dm755 "${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
+  install -Dm755 "${_pkgname}-server" "${pkgdir}/usr/bin/${_pkgname}-server"
+	install -Dm644 "COPYING" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
+}