openage-git new

2 files changed, 63 insertions, 0 deletions

diff --git a/openage-git/.gitignore b/openage-git/.gitignore
new file mode 100644
index 000000000..f1972d076
--- /dev/null
+++ b/openage-git/.gitignore
@@ -0,0 +1 @@
+openage
diff --git a/openage-git/PKGBUILD b/openage-git/PKGBUILD
new file mode 100755
index 000000000..93ceb462a
--- /dev/null
+++ b/openage-git/PKGBUILD
@@ -0,0 +1,62 @@
+# Maintainer: Erich Eckner <arch at eckner dot net>
+# Contributor: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
+# Contributor: fzerorubigd <fzero@rubi.gd>
+# Contributor: Emmanuel Gil Peyrot <linkmauve@linkmauve.fr>
+
+pkgname=openage-git
+pkgver=0.4.1.r972.gb496c05b2
+pkgrel=1
+pkgdesc="A free (as in freedom) clone of the Age of Empires II engine"
+arch=(x86_64 i486 i686 pentium4 arm armv6h armv7h aarch64)
+url="https://openage.sft.mx/"
+license=(GPL3)
+_pinned_dependencies=(
+  'gcc-libs=12.2.1'
+  'glibc>=2.37'
+  'libepoxy.so=0'
+  'libfontconfig.so=1'
+  'libfreetype.so=6'
+  'libharfbuzz.so=0'
+  'libncursesw.so=6'
+  'libnyan.so=1'
+  'libogg.so=0'
+  'libOpenGL.so=0'
+  'libopus.so=0'
+  'libpng=1.6.39'
+  'libprofiler.so=0'
+  'libvulkan.so=1'
+  'opusfile=0.12'
+  'qt6-base=6.4.2'
+  'qt6-declarative=6.4.2'
+  'sdl2=2.26.3'
+)
+depends=(ftgl sdl2_image eigen xdg-utils python-pillow python-numpy python-toml python-pygments python-jinja python-lz4 "${_pinned_dependencies[@]}")
+makedepends=(git cmake cython doxygen vulkan-headers python-graphviz)
+optdepends=('ttf-dejavu: for text display, but you can use any font'
+            vulkan-icd-loader)
+provides=(openage)
+conflicts=(openage)
+source=("git+https://github.com/SFTtech/openage")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${srcdir}/${pkgname%-git}"
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+prepare() {
+  cd "${srcdir}/${pkgname%-git}"
+  install -d build
+}
+build() {
+  cd "${srcdir}/${pkgname%-git}/build"
+
+  cmake .. \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
+    -DCMAKE_BUILD_TYPE=Release
+  make
+}
+package() {
+  cd "${srcdir}/${pkgname%-git}/build"
+  make DESTDIR="${pkgdir}/" install
+}