blob: 7d50d24c8c53fd685291fde633a56733e7bd91da (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Maintainer: Erich Eckner <arch at eckner dot net>
pkgbase=python-sphinx-better-theme
pkgname=(python2-sphinx-better-theme python-sphinx-better-theme)
_pkgname=sphinx-better-theme
pkgver=0.13
pkgrel=1
pkgdesc='theme for Sphinx that looks nice'
arch=('any')
url='https://sphinx-better-theme.readthedocs.io/'
license=('custom')
_deppy2=(
'python2>=2.7'
'python2<2.8'
)
_deppy=(
'python>=3.7'
'python<3.8'
)
_depends=()
_makedepends=()
_optdepends=()
source=("${_pkgname}-${pkgver}.tar.gz::https://github.com/irskep/${_pkgname}/archive/v${pkgver}.tar.gz")
sha512sums=('ad9b52205b29a410c918f789e5b4d110ca6bb654da18203206504efef7f16228b93b764cf14d9cca1a89d1850a4327b51f1f6fe7219d5968b5e51e5cf1935f42')
makedepends=(
"${_deppy[@]}"
"${_deppy2[@]}"
"${_depends[@]}"
"${_depends[@]//python/python2}"
"${_makedepends[@]}"
"${_makedepends[@]//ython/ython2}"
)
prepare() {
cp -r "${_pkgname}-${pkgver}" "py2-${_pkgname}-${pkgver}"
mv "${_pkgname}-${pkgver}" "py-${_pkgname}-${pkgver}"
}
build() {
cd "${srcdir}/py2-${_pkgname}-${pkgver}"
python2 setup.py build
cd "${srcdir}/py-${_pkgname}-${pkgver}"
python setup.py build
}
package_python2-sphinx-better-theme() {
depends=(
"${_deppy2[@]}"
"${_depends[@]//python/python2}"
)
optdepends=(
"${_optdepends[@]//python/python2}"
)
cd "${srcdir}/py2-${_pkgname}-${pkgver}"
python2 setup.py install --root="${pkgdir}/" --optimize=1
install -D LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
find "${pkgdir}/usr/bin" -maxdepth 1 -type f -printf '%f\n' | \
while read -r f; do
mv "${pkgdir}/usr/bin/${f}" "${pkgdir}/usr/bin/python2-${f}"
sed -i '1 s/python/python2/' "${pkgdir}/usr/bin/python2-${f}"
done
}
package_python-sphinx-better-theme() {
depends=(
"${_deppy[@]}"
"${_depends[@]}"
)
optdepends=(
"${_optdepends[@]}"
)
cd "${srcdir}/py-${_pkgname}-${pkgver}"
python setup.py install --root="${pkgdir}/" --optimize=1
install -D LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|
