blob: 69b9efe28b3e04f9421c6e1bce31361acc4b31c7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Leonid B <leonid dot bloch at esrf dot fr>
# Upstream contact: silx at esrf dot fr
pkgbase=python-pyfai
pkgname=(python2-pyfai python-pyfai)
_pkgname=pyFAI
pkgver=0.15.0
pkgrel='2'
pkgdesc="Fast Azimuthal Integration in Python."
arch=('i686' 'x86_64')
url="http://www.silx.org"
license=('GPLv3' 'BSD' 'MIT')
_deppy2=(
'python2>=2.7'
'python2<2.8'
)
_deppy=(
'python>=3.7'
'python<3.8'
)
_depends=('python-numpy' 'python-scipy' 'python-matplotlib' 'python-fabio'
'python-h5py' 'python-pyopencl' 'python-pyqt5' 'fftw' 'opencl-driver')
_makedepends=('cython')
_optdepends=()
source=("${_pkgname}-${pkgver}.tar.gz::https://github.com/silx-kit/${_pkgname}/archive/v${pkgver}.tar.gz")
sha256sums=('d72ae3b81ee4350e3768fd9ddc7a03ede4e33dbccddcba449cf1d563757c4726')
makedepends=(
"${_deppy[@]}"
"${_deppy2[@]}"
"${_depends[@]}"
"${_depends[@]//python/python2}"
"${_makedepends[@]}"
"${_makedepends[@]//ython/ython2}"
)
prepare() {
cp -r "${_pkgname}-${pkgver}" "py2-${_pkgname}-${pkgver}"
mv "${_pkgname}-${pkgver}" "py-${_pkgname}-${pkgver}"
}
build() {
cd "${srcdir}/py2-${_pkgname}-${pkgver}"
python2 setup.py build
cd "${srcdir}/py-${_pkgname}-${pkgver}"
python setup.py build
}
package_python2-pyfai() {
depends=(
"${_deppy2[@]}"
"${_depends[@]//python/python2}"
)
optdepends=(
"${_optdepends[@]//python/python2}"
)
cd "${srcdir}/py2-${_pkgname}-${pkgver}"
python2 setup.py install --root="${pkgdir}/" --optimize=1
install -D LICENSES.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -D copyright "${pkgdir}/usr/share/licenses/${pkgname}/COPYRIGHT"
find "${pkgdir}/usr/bin" -maxdepth 1 -type f -printf '%f\n' | \
while read -r f; do
mv "${pkgdir}/usr/bin/${f}" "${pkgdir}/usr/bin/python2-${f}"
sed -i '1 s/python/python2/' "${pkgdir}/usr/bin/python2-${f}"
done
}
package_python-pyfai() {
depends=(
"${_deppy[@]}"
"${_depends[@]}"
)
optdepends=(
"${_optdepends[@]}"
)
cd "${srcdir}/py-${_pkgname}-${pkgver}"
python setup.py install --root="${pkgdir}/" --optimize=1
install -D LICENSES.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -D copyright "${pkgdir}/usr/share/licenses/${pkgname}/COPYRIGHT"
}
|
