1 files changed, 89 insertions, 0 deletions
diff --git a/rxvt-unicode-better-wheel-scrolling/PKGBUILD b/rxvt-unicode-better-wheel-scrolling/PKGBUILD
new file mode 100644
index 00000000..458d4c31
--- /dev/null
+++ b/rxvt-unicode-better-wheel-scrolling/PKGBUILD
@@ -0,0 +1,89 @@
+# Maintainer: Erich Eckner <arch at eckner dot net>
+# Contributor: jjacky
+# Contributor: Angel Velasquez <angvp@archlinux.org> 
+# Contributor: tobias <tobias@archlinux.org>
+# Contributor: dibblethewrecker dibblethewrecker.at.jiwe.dot.org
+
+_pkgname=rxvt-unicode
+pkgname=${_pkgname}-better-wheel-scrolling
+pkgver=9.22
+pkgrel=5
+pkgdesc="An unicode enabled rxvt-clone terminal emulator (urxvt) w/ better wheel scrolling (VTE-like) (& no utmp/wtmp support)"
+arch=('i686' 'pentium4' 'x86_64')
+url="http://software.schmorp.de/pkg/rxvt-unicode.html"
+license=('GPL')
+_pinned_dependencies=(
+  'gcc-libs=10.2.0'
+  'glibc>=2.32'
+  'libfontconfig.so=1'
+  'libx11=1.7.0'
+  'libxft=2.3.3'
+  'libxrender=0.9.10'
+  'startup-notification=0.12'
+)
+depends=('rxvt-unicode-terminfo' 'perl' 'libnsl' "${_pinned_dependencies[@]}")
+optdepends=('gtk2-perl: to use the urxvt-tabbed')
+provides=("$_pkgname=$pkgver")
+conflicts=("$_pkgname")
+source=(http://dist.schmorp.de/rxvt-unicode/${_pkgname}-${pkgver}.tar.bz2 \
+        urxvt.desktop
+        urxvtc.desktop
+        urxvt-tabbed.desktop
+        secondaryWheel.patch)
+sha512sums=('b39f1b2cbe6dd3fbd2a0ad6a9d391a2b6f49d7c5e67bc65fe44a9c86937f8db379572c67564c6e21ff6e09b447cdfd4e540544e486179e94da0e0db679c04dd9'
+            '7184714a908071a4e8e5c065c5f90255e94dfd072df459c8d6f66fca3647781b3d1f6908b9303bcfd0d5b3f2e3822a8d66efaaa8a7c4d44f6e682839031a6e99'
+            'aa501eeeb220ba03b3f101b160230612efbca87694fef88c469b2976d29769c24b34576ea82f6c7941fad6039ac776f32e397add9b957b49bf2e84aeb67b66d6'
+            '18c7afb0c3eb8c832893b9ead09d25374b70ae1cd5479a5291d11794906c53daa6f1a1bf698b37efda062bb2b991cacac53a0a6c185ca416b8718fde2bb6a7af'
+            '9693b52c682ec71885962e197f55bc834ab7a6e51dda75947803e6094b01feaa9cd0628120e40522395efd538c15fd3c4edb9dac9b93c723260672b2b7af93b7')
+
+prepare() {
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+  patch -p1 -i ../secondaryWheel.patch
+}
+
+build() {
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+  ./configure \
+    --prefix=/usr \
+    --enable-256-color \
+    --enable-combining \
+    --enable-fading \
+    --enable-font-styles \
+    --enable-iso14755 \
+    --enable-keepscrolling \
+    --enable-lastlog \
+    --enable-mousewheel \
+    --enable-next-scroll \
+    --enable-perl \
+    --enable-pointer-blank \
+    --enable-rxvt-scroll \
+    --enable-selectionscrolling \
+    --enable-slipwheeling \
+    --disable-smart-resize \
+    --enable-startup-notification \
+    --enable-transparency \
+    --enable-unicode3 \
+    --enable-utmp \
+    --enable-wtmp \
+    --enable-xft \
+    --enable-xim \
+    --enable-xterm-scroll \
+    --disable-pixbuf \
+    --disable-frills
+  make
+}
+
+package() {
+  # install freedesktop menu
+  for _f in urxvt urxvtc urxvt-tabbed; do
+    install -Dm 644 ${_f}.desktop "${pkgdir}/usr/share/applications/${_f}.desktop"
+  done
+
+  cd "${_pkgname}-${pkgver}"
+  # workaround terminfo installation
+  export TERMINFO=/dev/null
+  make DESTDIR="${pkgdir}" install
+  # install the tabbing wrapper ( requires gtk2-perl! )
+  sed -i 's/\"rxvt\"/"urxvt"/' doc/rxvt-tabbed
+  install -Dm 755 doc/rxvt-tabbed "${pkgdir}/usr/bin/urxvt-tabbed"
+}