python-peakutils new

1 files changed, 53 insertions, 0 deletions

diff --git a/python-peakutils/PKGBUILD b/python-peakutils/PKGBUILD
new file mode 100644
index 00000000..bea7edce
--- /dev/null
+++ b/python-peakutils/PKGBUILD
@@ -0,0 +1,53 @@
+# Maintainer: Erich Eckner <arch at eckner dot net>
+# Contributor: Jakob Nixdorf <flocke@shadowice.org>
+
+pkgbase=python-peakutils
+pkgname=('python-peakutils' 'python2-peakutils')
+pkgver=1.1.1
+pkgrel=1
+pkgdesc="Peak detection utilities for 1D data"
+arch=('any')
+url="https://pypi.python.org/pypi/PeakUtils"
+license=('MIT')
+_depends=('python-numpy' 'python-scipy')
+_makedepends=('python-setuptools')
+makedepends=(
+  "${_depends[@]}" "${_depends[@]/python/python2}"
+  "${_makedepends[@]}" "${_makedepends[@]/python/python2}"
+)
+source=("https://pypi.python.org/packages/cf/a0/9e9c716221b541c8b919a5c36f098ef5a34329ea881ff44ff581b427a36a/PeakUtils-${pkgver}.tar.gz")
+md5sums=('edd12f75854195a7d955bc3276bca2b5')
+
+prepare() {
+  cd "${srcdir}"
+
+  cp -a "PeakUtils-${pkgver}" "${pkgname[0]}"
+  cp -a "PeakUtils-${pkgver}" "${pkgname[1]}"
+}
+
+build() {
+  cd "${srcdir}/${pkgname[0]}"
+  python setup.py build
+
+  cd "${srcdir}/${pkgname[1]}"
+  python2 setup.py build
+}
+
+package_python-peakutils() {
+  depends=(
+    "${_depends[@]}"
+  )
+
+  cd "${srcdir}/${pkgname[0]}"
+  python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1
+}
+
+package_python2-peakutils() {
+  depends=(
+    "${_depends[@]/python/python2}"
+  )
+
+  cd "${srcdir}/${pkgname[1]}"
+  python2 setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1
+}
+