From 16863fa14ecca5509442b578d7ce541325137698 Mon Sep 17 00:00:00 2001
From: Jim Meyering <jim@meyering.net>
Date: Sun, 14 Jan 2001 11:07:28 +0000
Subject: check for SunOS4.1.1U bug in rename

---
 m4/rename.m4 | 40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)
 create mode 100644 m4/rename.m4

(limited to 'm4')

diff --git a/m4/rename.m4 b/m4/rename.m4
new file mode 100644
index 000000000..cba3cd242
--- /dev/null
+++ b/m4/rename.m4
@@ -0,0 +1,40 @@
+#serial 1
+
+dnl From Volker Borchert.
+dnl Determine whether rename works for source paths with a trailing slash.
+dnl The rename from SunOS 4.1.1_U1 doesn't.
+dnl
+dnl If it doesn't, then define RENAME_TRAILING_SLASH_BUG and arrange
+dnl to compile the wrapper function.
+dnl
+
+AC_DEFUN(vb_FUNC_RENAME,
+[
+ AC_CACHE_CHECK([whether rename is broken],
+  vb_cv_func_rename_trailing_slash_bug,
+  [AC_TRY_RUN([
+#   include <stdio.h>
+
+    int
+    main ()
+    {
+      if (mkdir ("foo") < 0)
+        exit (1);
+      if (rename ("foo/", "bar") < 0)
+        { rmdir ("foo"); exit (1); }
+      else
+        { rmdir ("bar"); exit (0); }
+    }
+	  ],
+	 vb_cv_func_rename_trailing_slash_bug=no,
+	 vb_cv_func_rename_trailing_slash_bug=yes,
+	 dnl When crosscompiling, assume rename is broken.
+	 vb_cv_func_rename_trailing_slash_bug=yes)
+  ])
+  if test $vb_cv_func_rename_trailing_slash_bug = yes; then
+    AC_LIBOBJ(rename)
+    AC_DEFINE_UNQUOTED(RENAME_TRAILING_SLASH_BUG, 1,
+[Define if rename does not work for source paths with a trailing slash,
+   like the one from SunOS 4.1.1_U1. ])
+  fi
+])
-- 
cgit v1.2.3-54-g00ecf