From 4da3feb0e90b26ce4acf23c0eec5194d00b9a564 Mon Sep 17 00:00:00 2001
From: Jim Meyering <jim@meyering.net>
Date: Fri, 6 Feb 1998 12:36:04 +0000
Subject: .

---
 m4/perl.m4 | 39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)
 create mode 100644 m4/perl.m4

(limited to 'm4/perl.m4')

diff --git a/m4/perl.m4 b/m4/perl.m4
new file mode 100644
index 000000000..0cc681ccd
--- /dev/null
+++ b/m4/perl.m4
@@ -0,0 +1,39 @@
+#serial 1
+
+dnl From Jim Meyering.
+dnl Find a new-enough version of Perl.
+dnl
+
+AC_DEFUN(jm_PERL,
+[
+  dnl FIXME: don't hard-code 5.003
+  dnl FIXME: should we cache the result?
+  AC_MSG_CHECKING([for perl5.003 or newer])
+  if test "${PERL+set}" = set; then
+    # `PERL' is set in the user's environment.
+    candidate_perl_names="$PERL"
+    perl_specified=yes
+  else
+    candidate_perl_names='perl perl5'
+    perl_specified=no
+  fi
+
+  found=no
+  AC_SUBST(PERL)
+  PERL="$missing_dir/missing perl"
+  for perl in $candidate_perl_names; do
+    # Run test in a subshell; some versions of sh will print an error if
+    # an executable is not found, even if stderr is redirected.
+    if ( $perl -e 'require 5.003' ) > /dev/null 2>&1; then
+      PERL=$perl
+      found=yes
+      break
+    fi
+  done
+
+  AC_MSG_RESULT($found)
+  test $found = no && AC_MSG_WARN([
+*** You don't seem to have perl5.003 or newer installed.
+*** Because of that, you may be unable to regenerate certain files
+*** if you modify the sources from which they are derived.] )
+])
-- 
cgit v1.2.3-54-g00ecf