python-jupyter_telemetry/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33

# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Blair Bonnett <blair dot bonnett at gmail dot com>

pkgname=python-jupyter_telemetry
pkgver=0.1.0
pkgrel=2
pkgdesc="Configurable event-logging for Jupyter applications and extensions"
url="https://github.com/jupyter/telemetry"
arch=('any')
license=('BSD')
depends=('python-json-logger' 'python-jsonschema' 'python-ruamel-yaml' 'python-traitlets')
makedepends=('git' 'python-setuptools')
checkdepends=('python-pytest')
source=(
  "telemetry-${pkgver}.tar.gz::https://github.com/jupyter/telemetry/archive/v${pkgver}.tar.gz"
)
sha512sums=('47d727d3a6c0d0e1b05811ee240ce8fa249169a7f59e88129275afc0956e61882bec539b7fc3f2830d1441b1c508e833bc5a97c4f2bcb901a82cdbc2c81f5652')

build() {
    cd "telemetry-${pkgver}"
    python setup.py build
}

check() {
    cd "telemetry-${pkgver}"
    PYTHONPATH="$PWD/build/lib:$PYTHONPATH" PYTHONDONTWRITEBYTECODE=1 pytest -v
}

package() {
    cd "telemetry-${pkgver}"
    python setup.py install --root="$pkgdir/" --prefix=/usr --optimize=1 --skip-build
    install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}