perl-xmlrpc-lite/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer:  Erich Eckner <arch at eckner dot net>
# Contributor: Yardena Cohen <yardenack at gmail dot com>

_cpanname=XMLRPC-Lite
_cpanauthor=PHRED
pkgname=perl-xmlrpc-lite
pkgver=0.717
pkgrel=8
_distdir="${_cpanname}-${pkgver}"
pkgdesc="client and server implementation of XML-RPC protocol"
arch=('any')
url="http://search.cpan.org/dist/${_cpanname}/"
license=('unknown')
options=('!emptydirs')
depends=(
  'perl>=5.32'
  'perl<5.33'
  'perl-soap-lite>=0.716')
makedepends=(
  'perl-extutils-makemaker')
source=("http://search.cpan.org/CPAN/authors/id/${_cpanauthor::1}/${_cpanauthor::2}/${_cpanauthor}/${_distdir}.tar.gz")
sha256sums=('3a9fa5f2cb1faf8b7c66b4c386eab35cac6088afc4dbc757d4f77d284dab4524')

build() {
	 cd "${srcdir}/${_distdir}"
	 perl Makefile.PL
	 make
}

check() {
	 cd "${srcdir}/${_distdir}"
	 make test
}

package () {
	 cd "${srcdir}/${_distdir}"
	 make install INSTALLDIRS=vendor DESTDIR="${pkgdir}"
}