blob: 9597b008453abeebb1a7753ee61917bd46fc2b6b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Maintainer: Erich Eckner <arch at eckner dot net>
pkgname='perl-mojolicious'
pkgver=9.19
pkgrel=1
pkgdesc='Web development toolkit'
arch=('any')
license=('PerlArtistic' 'GPL')
options=('!emptydirs')
depends=(
'perl-io-socket-ip>=0.37'
'perl-scalar-list-utils>=1.41')
makedepends=(
'perl-extutils-makemaker')
checkdepends=(
'perl-ev>=4'
'perl-io-socket-socks>=0.64'
'perl-io-socket-ssl>=1.94'
'perl-role-tiny'
'perl-test-pod'
'perl-test-pod-coverage')
url='https://metacpan.org/release/Mojolicious'
_distdir="Mojolicious-${pkgver}"
source=("https://cpan.metacpan.org/authors/id/S/SR/SRI/${_distdir}.tar.gz")
sha512sums=('14c29473f040548de2efef8bf5cd5676554f9f518b52e0ee03ed30415942fbeff5f5f2a6dd7592798e433e3e83653ce815697d4614e4680c9a6b8c699b0a171a')
prepare() {
cd "$srcdir/$_distdir"
rm t/mojo/websocket_proxy_tls.t
rm t/mojo/tls.t
rm t/mojo/ioloop_tls.t
}
build() {
( export PERL_MM_USE_DEFAULT=1 PERL5LIB="" \
PERL_AUTOINSTALL=--skipdeps \
PERL_MM_OPT="INSTALLDIRS=vendor DESTDIR='$pkgdir'" \
PERL_MB_OPT="--installdirs vendor --destdir '$pkgdir'" \
MODULEBUILDRC=/dev/null
cd "$srcdir/$_distdir"
perl Makefile.PL
make
)
}
check() {
cd "$srcdir/$_distdir"
( export PERL_MM_USE_DEFAULT=1 PERL5LIB=""
export TEST_EV=1
export TEST_HYPNOTOAD=1
export TEST_IPV6=1
export TEST_MORBO=1
export TEST_ONLINE=1
export TEST_POD=1
export TEST_PREFORK=1
export TEST_SOCKS=1
export TEST_SUBPROCESS=1
export TEST_TLS=1
export TEST_UNIX=1
make test
)
}
package() {
cd "$srcdir/$_distdir"
make install
find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
}
# Local Variables:
# mode: shell-script
# sh-basic-offset: 2
# End:
# vim:set ts=2 sw=2 et:
|
