blob: 94f632e27fdfa5f746dbd9a71a362e0f2f9338dd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# $Id$
# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: James Rayner <james@archlinux.org>
# Contributor: Partha Chowdhury <kira.laucas@gmail.com>
pkgname=conky-irc
pkgver=1.11.5
provides=("conky=${pkgver}")
conflicts=('conky')
pkgrel=31
pkgdesc='Lightweight system monitor for X - with irc-client enabled'
url='https://github.com/brndnmtthws/conky'
license=('BSD' 'GPL')
arch=('i686' 'pentium4' 'x86_64')
makedepends=('cmake' 'docbook2x' 'docbook-xml' 'man-db' 'git')
depends=('glib2' 'lua' 'wireless_tools' 'libxdamage' 'libxinerama' 'libxft'
'imlib2' 'libxml2' 'libpulse' 'libircclient')
optdepends=('mounted')
source=("${pkgname%-irc}-${pkgver}.tar.gz::https://github.com/brndnmtthws/conky/archive/v${pkgver}.tar.gz"
'MAX_SP.patch')
sha512sums=('71ba02acc879dad3c240ed9a38635cb2d30e3c9ac849012ff3db53f8143c28d6cc9e502816834b0a073f7486bded7cea002b58c3bb8e189e542afb1070bb84be'
'1ea39f88b5f2620fc0c4485cc16645dbad91f97be17b4b13a732205dde6265d621c7f2bc92be33b65f9db2815312beb42b516ddebbba90cfe947104e1a410a52')
# options=('!strip' 'debug')
prepare() {
cd "${srcdir}/${pkgname%-irc}-${pkgver}"
patch -p1 -i ../MAX_SP.patch
sed '/^#include / s,<libircclient\.h>,<libircclient/libircclient.h>,' -i 'src/irc.cc'
sed '/check_include_files(/ s,libircclient\.h,libircclient/libircclient.h,' -i 'cmake/ConkyPlatformChecks.cmake'
}
build() {
cd "${srcdir}/${pkgname%-irc}-${pkgver}"
cmake \
-D CMAKE_BUILD_TYPE=Release \
-D MAINTAINER_MODE=ON \
-D BUILD_WLAN=ON \
-D BUILD_XDBE=ON \
-D BUILD_XSHAPE=ON \
-D BUILD_IMLIB2=ON \
-D BUILD_CURL=ON \
-D BUILD_RSS=ON \
-D BUILD_WEATHER_METAR=ON \
-D BUILD_WEATHER_XOAP=ON \
-D BUILD_PULSEAUDIO=ON \
-D BUILD_JOURNAL=ON \
-D BUILD_IRC=ON \
-D CMAKE_INSTALL_PREFIX=/usr \
.
make
}
package() {
cd "${srcdir}/${pkgname%-irc}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 extras/vim/syntax/conkyrc.vim "${pkgdir}"/usr/share/vim/vimfiles/syntax/conkyrc.vim
install -Dm644 extras/vim/ftdetect/conkyrc.vim "${pkgdir}"/usr/share/vim/vimfiles/ftdetect/conkyrc.vim
}
|
