# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Gordian Edenhofer <gordian.edenhofer@gmail.com>

pkgname=zoom
pkgver=5.13.5.431
_build=${pkgver#*.*.*.}
_pkgver=${pkgver%.${_build}}
pkgrel=21
pkgdesc="Video Conferencing and Web Conferencing Service"
arch=('x86_64')
license=('custom')
url="https://zoom.us/"
_pinned_dependencies=(
  'gcc-libs=12.2.1'
  'glibc>=2.35'
  'libasound.so=2'
  'libatk-1.0.so=0'
  'libatk-bridge-2.0.so=0'
  'libatspi.so=0'
  'libcairo-gobject.so=2'
  'libcairo.so=2'
  'libcups=1:2.4.2'
  'libdbus-1.so=3'
  'libdrm=2.4.115'
  'libEGL.so=1'
  'libexpat.so=1'
  'libfontconfig.so=1'
  'libfreetype.so=6'
  'libgdk-3.so=0'
  'libgdk_pixbuf-2.0.so=0'
  'libgio-2.0.so=0'
  'libglib-2.0.so=0'
  'libGL.so=1'
  'libgmodule-2.0.so=0'
  'libgobject-2.0.so=0'
  'libgssapi_krb5.so=2'
  'libgthread-2.0.so=0'
  'libgtk-3.so=0'
  'libicudata.so=72'
  'libicui18n.so=72'
  'libicuuc.so=72'
  'libpango-1.0.so=0'
  'libpangocairo-1.0.so=0'
  'libpulse-mainloop-glib.so=0'
  'libpulse.so=0'
  'libwayland-client.so=0'
  'libwayland-cursor.so=0'
  'libwayland-egl.so=1'
  'libx11=1.8.4'
  'libxcb=1.15'
  'libxcomposite=0.4.6'
  'libxdamage=1.1.6'
  'libxext=1.3.5'
  'libxfixes=6.0.1'
  'libxkbcommon.so=0'
  'libxkbcommon-x11.so=0'
  'libxrandr=1.5.3'
  'libxtst=1.2.4'
  'mesa=23.0.3'
  'nspr=4.35'
  'nss=3.89'
  'xcb-util-image=0.4.1'
  'xcb-util-keysyms=0.4.1'
  'zlib=1:1.2.13'
)
depends=('fontconfig' 'glib2' 'libpulse' 'libsm' 'ttf-font' 'libx11' 'libxtst' 'libxcb'
	'libxcomposite' 'libxfixes' 'libxi' 'libxcursor' 'libxkbcommon-x11' 'libxrandr'
	'libxrender' 'libxshmfence' 'libxslt' 'mesa' 'nss' 'xcb-util-image'
	'xcb-util-keysyms' 'dbus' 'ibus' "${_pinned_dependencies[@]}")
optdepends=('pulseaudio-alsa: audio via PulseAudio'
	'qt5-webengine: SSO login support'
	'picom: extra compositor needed by some window managers for screen sharing'
	'xcompmgr: extra compositor needed by some window managers for screen sharing')
options=(!strip)
source=("${pkgname}-${pkgver}_orig_x86_64.pkg.tar.xz"::"https://zoom.us/client/${_pkgver}.${_build}/zoom_x86_64.pkg.tar.xz")
sha512sums=('d23dac59609658f4869cec5aeed01e3e03f8b85708915c430ab3b05727501039c24844ab88c124bb6df121aacc805fdf9bfd8e49673976b45121cf793c07c431')

prepare() {
	sed -i 's/Zoom\.png/Zoom/g' "${srcdir}/usr/share/applications/Zoom.desktop"
	sed -i 's/StartupWMClass=Zoom/StartupWMClass=zoom/g' "${srcdir}/usr/share/applications/Zoom.desktop"
}

package() {
	cp -dpr --no-preserve=ownership opt usr "${pkgdir}"
}