# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: epitron <chris@ill-logic.com>

pkgname=wcc-git
_pkgname=wcc
pkgver=0.0.2.r37.g8254480
pkgrel=6
pkgdesc="The Witchcraft Compiler Collection"
arch=('i486' 'i686' 'pentium4' 'x86_64')
license=('MIT')
_pinned_dependencies=(
  'glibc>=2.33'
  'libcapstone.so=5'
  'libelf=0.191'
  'libsframe.so=1'
  'libz.so=1'
  'libzstd.so=1'
)
depends=(binutils readline gsl "${_pinned_dependencies[@]}")
makedepends=(git make)
provides=(wcc=${pkgver%.r*.g*})
conflicts=(wcc)
url=https://github.com/endrazine/wcc
source=("git+https://github.com/endrazine/wcc.git")
sha512sums=('SKIP')

pkgver() {
  cd "$_pkgname"
  git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}

prepare() {
  cd "$_pkgname"
  git submodule init
  git submodule update
}

build() {
  cd "$_pkgname"
  make
}

package() {
  cd "$_pkgname"
  install -d "${pkgdir}/usr/bin"
  make DESTDIR="${pkgdir}/" install

  # install manpages
  install -d "${pkgdir}/usr/share/man/man1/"
  install -pm 644 doc/manpages/* $pkgdir/usr/share/man/man1
}