# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: "Amhairghin" Oscar Garcia Amor (https://ogarcia.me)

pkgname=teams
pkgver=1.5.00.23861
pkgrel=15
pkgdesc="Microsoft Teams for Linux is your chat-centered workspace in Office 365"
arch=('x86_64')
url="https://teams.microsoft.com/downloads"
license=('custom')
_pinned_dependencies=(
  'gcc-libs=12.2.1'
  'glibc>=2.35'
  'libasound.so=2'
  'libatk-1.0.so=0'
  'libatk-bridge-2.0.so=0'
  'libatspi.so=0'
  'libcairo.so=2'
  'libcups=1:2.4.2'
  'libdbus-1.so=3'
  'libdrm=2.4.114'
  'libexpat.so=1'
  'libgdk-3.so=0'
  'libgdk_pixbuf-2.0.so=0'
  'libgio-2.0.so=0'
  'libglib-2.0.so=0'
  'libgobject-2.0.so=0'
  'libgtk-3.so=0'
  'libpango-1.0.so=0'
  'libpangocairo-1.0.so=0'
  'libsecret-1.so=0'
  'libx11=1.8.4'
  'libxcb=1.15'
  'libxcomposite=0.4.6'
  'libxcursor=1.2.1'
  'libxdamage=1.1.6'
  'libxext=1.3.5'
  'libxfixes=6.0.0'
  'libxi=1.8'
  'libxrandr=1.5.3'
  'libxrender=0.9.11'
  'libxtst=1.2.4'
  'mesa=22.3.4'
  'nspr=4.35'
  'nss=3.88.1'
)
depends=("gtk3" "libxss" "alsa-lib" "libxtst" "libsecret" "nss" "glibc>=2.28-4" "${_pinned_dependencies[@]}")
makedepends=(nodejs-lts-fermium)
optdepends=("libappindicator-gtk3: Systray indicator support"
            "org.freedesktop.secrets: Keyring password store support")
conflicts=("ms-teams")
replaces=("ms-teams")
source=("https://packages.microsoft.com/repos/ms-teams/pool/main/t/teams/${pkgname}_${pkgver}_amd64.deb")
noextract=("${pkgname}_${pkgver}_amd64.deb")
sha512sums=('04a6199343af844e14d24fd78c659c1055c277f3832a00984915c20abb4d4c59a7ce4629b4c1340a634b4ab82f2329f9830bf77b40fce53ca4b54973451c3f29')

package() {
  depends+=('nodejs>=14' 'nodejs<17')
  bsdtar -O -xf "${pkgname}_${pkgver}_amd64.deb" data.tar.xz | bsdtar -C "${pkgdir}" -xJf -

  # Permissions fix
  find "${pkgdir}" -type d -exec chmod 755 {} \;

  # Move license
  install -dm755 "${pkgdir}/usr/share/licenses/${pkgname}"
  mv "${pkgdir}/usr/share/${pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}"
  ln -s "/usr/share/licenses/${pkgname}/LICENSE" "${pkgdir}/usr/share/${pkgname}/LICENSE"
}