# $Id: PKGBUILD 266875 2017-11-15 14:29:11Z foutrelis $
# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Roman Kyrylych <roman@archlinux.org>
# Contributor: Michal Kaliszka <desmont@gmail.com>
# Contributor: Zsolt Varadi <sysop_xxl@fibermail.hu>
# Contributor: Holger Rauch < holger dot rauch at posteo dot de >

pkgname=tea-qt
pkgver=63.2.0
pkgrel=2
pkgdesc="A Qt-based text editor for Linux and *BSD with an ultimate small size, providing hundreds of functions"
arch=('i686' 'pentium4' 'x86_64')
url="http://semiletov.org/tea/"
license=('GPL')
_pinned_dependencies_x86_64=(
  'aspell=0.60.8.1'
  'gcc-libs=14.2.1+r134+gab884fffe3fc'
)
_pinned_dependencies=(
  'djvulibre=3.5.28'
  'glibc>=2.31'
  'hunspell=1.7.2'
  'libpoppler-qt5.so=1'
  'libz.so=1'
  'qt5-base=5.15.16+kde+r130'
)
depends=('qt5-declarative' 'desktop-file-utils' "${_pinned_dependencies[@]}")
depends_x86_64=("${_pinned_dependencies_x86_64[@]}")
makedepends=('cmake')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/psemiletov/tea-qt/archive/${pkgver}.tar.gz")
sha512sums=('ff895fc5db43e2b297d0def56703f622091348fed4baf8c98eef94ece8cb0ff3011b1737e04ffe3c41a33c6224a1e040e384d160a31df77f466a2bedc617b541')
provides=("tea=${pkgver}")
conflicts=('tea')
replaces=('tea')

build() {
  mkdir -p "${srcdir}/${pkgname}-${pkgver}/b"
  cd "${srcdir}/${pkgname}-${pkgver}/b"
  cmake .. -DCMAKE_INSTALL_PREFIX=/usr
  make
}

package(){
  cd "${srcdir}/${pkgname}-${pkgver}/b"
  make DESTDIR="${pkgdir}" install
}