# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: "Amhairghin" Oscar Garcia Amor (https://ogarcia.me)
# Contributor: Simon Gomizelj <simongmzlj(at)gmail(dot)com>
# Contributor: Kyle Manna <kyle(at)kylemanna(dot)com>

pkgname=slack-desktop
pkgver=4.29.149
pkgrel=37
pkgdesc="Slack Desktop (Beta) for Linux"
arch=('x86_64')
url="https://slack.com/downloads"
license=('custom')
_pinned_dependencies=(
  'gcc-libs=13.1.1'
  'glibc>=2.33'
  'libasound.so=2'
  'libatk-1.0.so=0'
  'libatk-bridge-2.0.so=0'
  'libatspi.so=0'
  'libcairo.so=2'
  'libcups=1:2.4.3'
  'libdbus-1.so=3'
  'libdrm=2.4.115'
  'libexpat.so=1'
  'libgio-2.0.so=0'
  'libglib-2.0.so=0'
  'libgobject-2.0.so=0'
  'libgtk-3.so=0'
  'libpango-1.0.so=0'
  'libwayland-client.so=0'
  'libx11=1.8.5'
  'libxcb=1.15'
  'libxcomposite=0.4.6'
  'libxdamage=1.1.6'
  'libxext=1.3.5'
  'libxfixes=6.0.1'
  'libxkbcommon.so=0'
  'libxrandr=1.5.3'
  'mesa=23.1.1'
  'nspr=4.35'
  'nss=3.89.1'
)
depends=('alsa-lib' 'gtk3' 'libsecret' 'libxss' 'libxtst' 'nss' 'xdg-utils' "${_pinned_dependencies[@]}")
optdepends=('libappindicator-gtk3: Systray indicator support'
            'org.freedesktop.secrets: Keyring password store support')
source_x86_64=("https://downloads.slack-edge.com/releases/linux/${pkgver}/prod/x64/${pkgname}-${pkgver}-amd64.deb")
source=("${pkgname}.patch")
sha512sums=('fd7e9681887639a2a9117c6bf537c25918f02985588366aaf3cd5b2e07b842d773aaf27354b7c149df1cc003e645b77bd36ec753992d50e02f5eb87e59009264')
sha512sums_x86_64=('9771af26efdadfe7eed5945b57900360b50804642e62db42cb2af20c3246edfdadf491deb2d1004a02e6dc545def079ecf6ab175e4d27f1989bcc8cbaf12366c')

package() {
    cd "${pkgdir}"
    bsdtar -xJf "${srcdir}/data.tar.xz"

    # Fix hardcoded icon path in .desktop file
    patch -p1 -i "${srcdir}/${pkgname}.patch"

    # Remove all unnecessary stuff
    rm -rf --one-file-system \
      "etc" \
      "usr/lib/slack/src" \
      "usr/share/lintian" \
      "usr/share/doc"

    # Move license
    install -dm755 "usr/share/licenses/${pkgname}"
    mv "usr/lib/slack/LICENSE" "usr/share/licenses/${pkgname}"
    ln -s "/usr/share/licenses/${pkgname}/LICENSE" "usr/lib/slack/LICENSE"
}