# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Xyne <ac xunilhcra enyx, backwards>
# repo: releng
pkgname=reflector32
pkgver=2021.4
pkgrel=1
pkgdesc='A Python 3 module and script to retrieve and filter the latest Pacman mirror list for Archlinux32.'
arch=(any)
license=(GPL)
url="https://xyne.archlinux.ca/projects/reflector"
depends=(python3)
optdepends=('rsync: rate rsync mirrors')
backup=(etc/xdg/reflector/reflector32.conf)
source=(
  "https://sources.archlinux32.org/sources/reflector32-${pkgver}.tar.gz"{,.sig}
)
sha512sums=('aebf2c041a9be356da872fbae45c1913dd2ac8cae029112d2d2984d3e3ff06a416ab52af86474d5f5f0f3c82a793fa115ff8650b8231837e9f2cd67f338e267c'
            'SKIP')
validpgpkeys=('DE9F7688CACF04FEB81A6C590AEEC90755DA7B5A' '38ACA6A026D25CDD227D24832F6399DCD2212195')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  sed -i 's/\b[Rr]eflector\b/\032/g' setup.py reflector Reflector.py
  mv reflector{,32}
  mv Reflector{,32}.py
}

package ()
{
  cd "$srcdir/$pkgname-$pkgver"
  python3 setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
  install -Dm644 "man/${pkgname%32}.1.gz" "${pkgdir}/usr/share/man/man1/${pkgname}.1.gz"
  install -Dm644 'reflector.service' "$pkgdir/usr/lib/systemd/system/reflector32.service"
  install -Dm644 'reflector.timer' "$pkgdir/usr/lib/systemd/system/reflector32.timer"
  install -Dm644 'reflector.conf' "$pkgdir/etc/xdg/reflector/reflector32.conf"
}


# vim: set ts=2 sw=2 et: