# Maintainer: Erich Eckner <arch at eckner dot net>
pkgname=python-jira
_pkgname="${pkgname#*-}"
pkgver=3.4.1
pkgrel=2
pkgdesc="Python library to work with Jira APIs"
arch=(any)
url="https://github.com/pycontribs/jira"
license=('BSD')
depends=(
  'python>=3.11'
  'python<3.12')
makedepends=(
  'python-pip'
  'python-setuptools')
source=("$_pkgname-$pkgver.tar.gz::https://github.com/pycontribs/jira/archive/refs/tags/$pkgver.tar.gz"
setup.py)
sha512sums=('76ce26b480ed51ab08b15828e2433ac0e4208102c5747b720117d0daa74f943055ea7bc247d86ab4af12d42390330efb12d2893cb8cc0b1d0300e16c084604e5'
            '373dacad848dfd8a23d84bf329f9f2090689789361adcbf6f0fbe11ef7c5d7599039805f2f7b6c52d07e1f4b7980150f3e015fa9b0392b7c7318b1068976bc9e')

prepare() {
  cd "${srcdir}/jira-${pkgver}"
  sed '
    s@\(setuptools.setup(\)use_scm_version=True)@\1version='"'${pkgver}'"')@
  ' ../setup.py > setup.py
}

package() {
  cd "${srcdir}/jira-${pkgver}"
  python setup.py install --root="$pkgdir" --optimize=1
  install -Dm 644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}