# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Piotr Rogoża <piotr dot r dot public at gmail dot com>

pkgname=perl-file-find-object
pkgver=0.3.5
pkgrel=3
_author="S/SH/SHLOMIF"
_distdir="File-Find-Object-${pkgver}"
pkgdesc="File::Find::Object - An object oriented File::Find replacement"
arch=('any')
url="http://search.cpan.org/dist/File-Find-Object/"
license=('GPL' 'PerlArtistic')
makedepends=(
  'perl'
  'perl-extutils-makemaker'
  'perl-file-path'
  'perl-io'
  'perl-lib'
  'perl-module-build>=0.28'
  'perl-test-simple>=0.88')
depends=(
  'perl>=5.34'
  'perl<5.35'
  'perl-carp'
  'perl-class-xsaccessor'
  'perl-parent'
  'perl-pathtools'
  'perl-scalar-list-utils')
provides=(
  'perl-file-find-object-base=0.3.5'
  'perl-file-find-object-deeppath=0.3.5'
  'perl-file-find-object-pathcomp=0.3.5'
  'perl-file-find-object-result=0.3.5'
  'perl-file-find-object-toppath=0.3.5')
checkdepends=(
  'perl'
  'perl-cpan-changes'
  'perl-pod-coverage-trustpod'
  'perl-test-kwalitee-extra'
  'perl-test-pod'
  'perl-test-pod-coverage'
  'perl-test-simple'
  'perl-test-trailingspace'
)
options=(!emptydirs)
source=("http://search.cpan.org/CPAN/authors/id/$_author/${_distdir}.tar.gz")
sha512sums=('0260f9b82cc742078f272544cf1e5bd021aefc234833e84f655a94b6e43dab2d6ce900490ab60fc4fb1977beed89003dabd90deffffd12d45c5987e6d4fa6f9d')

build(){
  cd "$srcdir/${_distdir}"

  # Setting these env variables overwrites any command-line-options we don't want...
  export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps \
    PERL_MM_OPT="INSTALLDIRS=vendor DESTDIR='$pkgdir'" \
    PERL_MB_OPT="--installdirs vendor --destdir '$pkgdir'" \
    MODULEBUILDRC=/dev/null

  # If using Makefile.PL
  if [ -r Makefile.PL ]; then
    /usr/bin/perl Makefile.PL
    make
  # If using Build.PL
  elif [ -r Build.PL ]; then
    /usr/bin/perl Build.PL
    perl Build
  fi
}
check(){
  cd "$srcdir/${_distdir}"

  export AUTHOR_TESTING=1
  export RELEASE_TESTING=1

  # If using Makefile.PL
  if [ -r Makefile.PL ]; then
    make test
  # If using Build.PL
  elif [ -r Build.PL ]; then
    perl Build test
  fi
}
package(){
  cd "$srcdir/${_distdir}"

  # If using Makefile.PL
  if [ -r Makefile.PL ]; then
    make install
  # If using Build.PL
  elif [ -r Build.PL ]; then
    perl Build install
  fi

  # remove perllocal.pod and .packlist
  find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
}