# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
# Contributor: fzerorubigd <fzero@rubi.gd>
# Contributor: Emmanuel Gil Peyrot <linkmauve@linkmauve.fr>

pkgname=openage-git
pkgver=0.5.3.r450.g66098cea4
pkgrel=3
pkgdesc="A free (as in freedom) clone of the Age of Empires II engine"
arch=(x86_64 i486 i686 pentium4 arm armv6h armv7h aarch64)
url="https://openage.sft.mx/"
license=(GPL3)
_pinned_dependencies=(
  'gcc-libs=14.2.1+r134+gab884fffe3fc'
  'glibc>=2.37'
  'gperftools=2.15'
  'libepoxy.so=0'
  'libfontconfig.so=1'
  'libfreetype.so=6'
  'libharfbuzz.so=0'
  'libncursesw.so=6'
  'libnyan.so=1'
  'libogg.so=0'
  'libOpenGL.so=0'
  'libopus.so=0'
  'libpng16.so=16'
  'libvulkan.so=1'
  'opusfile=0.12'
  'qt6-base=6.7.3'
  'qt6-declarative=6.7.3'
  'sdl2=2.30.8'
)
depends=(ftgl sdl2_image eigen xdg-utils python-pillow python-numpy python-toml python-pygments python-jinja python-lz4 "${_pinned_dependencies[@]}")
makedepends=(git cmake cython doxygen vulkan-headers python-graphviz python-mako)
optdepends=('ttf-dejavu: for text display, but you can use any font'
            vulkan-icd-loader)
provides=(openage)
conflicts=(openage)
source=("git+https://github.com/SFTtech/openage")
sha512sums=('SKIP')

pkgver() {
  cd "${srcdir}/${pkgname%-git}"
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
  cd "${srcdir}/${pkgname%-git}"
  install -d build
}
build() {
  cd "${srcdir}/${pkgname%-git}/build"

  cmake .. \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
    -DCMAKE_BUILD_TYPE=Release
  make
}
package() {
  cd "${srcdir}/${pkgname%-git}/build"
  make DESTDIR="${pkgdir}/" install
}