# Maintainer: Erich Eckner <arch at eckner dot net>
arch=('x86_64')
pkgbase='mandos'
pkgname=('mandos-server' 'mandos-client-nokey')
pkgdesc='system for allowing servers with encrypted root file systems to reboot unattended and/or remotely'
pkgver=1.8.18
pkgrel=1
url='https://www.recompile.se/mandos'
license=('GPL')

source=("https://ftp.recompile.se/pub/${pkgbase}/${pkgbase}_${pkgver}.orig.tar.gz"
        "https://ftp.recompile.se/pub/${pkgbase}/${pkgbase}_${pkgver}.orig.tar.gz.asc"
        mandos.init)

sha512sums=('d900e02f806d305113361c27e42a8f40043d1cf46c21ee1d22fab338e3699f9bc570bd11f809a750236e35b921036164934022627fd38ea04b1342153600d0c8'
            'SKIP'
            'f0c8d97a20d4dac9aad1f886ecb07bd54254c73c2caa02342c6c4cf4f278309bea59250e0f0c1088ae935e0f9823f82094405d6d285ad15f5157b6f207873c35')

validpgpkeys=('153A37F10BBA0435987F2C4A72232973CA34C2C4')

depends=(avahi)
makedepends=(docbook-xsl libnl man-db)

prepare() {
  cd "$srcdir/$pkgbase-$pkgver"
  sed -i '
    /docbook\.xsl/ s@/stylesheet/nwalsh/@/'"$(
      ls /usr/share/xml/docbook/ \
      | grep -wF xsl-stylesheets \
      | grep -vwF nons \
      | sort -V \
      | tail -n1
    )"'/@
  ' Makefile
}

build() {
  cd "$srcdir/$pkgbase-$pkgver"
  make all doc
  find . -type f \( -name '*.8' -o -name '*.8mandos' -o -name '*.5' \) -exec sed -i 's@^\s\+@@' {} +
}

_package() {
  cd "$srcdir/$pkgbase-$pkgver"
  make install-$1 DESTDIR="$pkgdir" BINDIR="$pkgdir/usr/bin"
}

package_mandos-server() {
  arch=(any)
  _pinned_dependencies=(
  )
  depends=(
    'avahi-openrc'
    'python-gobject'
    'python-urwid'
  )
  _package server
  install -m755 "${srcdir}/mandos.init" "${pkgdir}/etc/init.d/mandos"
}

package_mandos-client-nokey() {
  _pinned_dependencies=(
    'avahi=1:0.8+r194+g3f79789'
    'gcc-libs=14.2.1+r134+gab884fffe3fc'
    'glib2=2.82.4'
    'glibc>=2.38'
    'gnutls=3.8.8'
    'gpgme=1.24.1'
    'libnl=3.11.0'
  )
  depends+=("${_pinned_dependencies[@]}")
  _package client-nokey
}