# Maintainer: Erich Eckner <arch at eckner dot net>
arch=('x86_64')
pkgbase='mandos'
pkgname=('mandos-server' 'mandos-client-nokey')
pkgdesc='system for allowing servers with encrypted root file systems to reboot unattended and/or remotely'
pkgver='1.8.17'
pkgrel=2
url='https://www.recompile.se/mandos'
license=('GPL')

source=("https://ftp.recompile.se/pub/${pkgbase}/${pkgbase}_${pkgver}.orig.tar.gz"
        "https://ftp.recompile.se/pub/${pkgbase}/${pkgbase}_${pkgver}.orig.tar.gz.asc"
        Makefile.patch)

sha512sums=('0059593ab6b92b5178bbbf0be5d6852ec93393ed39032b05bc54c20c698a9e000c1db6c5069fad40f4d173f5b9d397503ca0077446ef460571138fac0f33f5ea'
            'SKIP'
            '6561dfcd1c7ecc593b5d387796b01507fea7c1eb737196b880ac90c3ee561d4c7a803e2b21dc16d4c617ae116a7817465d99fa466398f53e4d7508ef8354110f')

validpgpkeys=('153A37F10BBA0435987F2C4A72232973CA34C2C4')

depends=(avahi)
makedepends=(docbook-xsl libnl man-db)

prepare() {
  cd "$srcdir/$pkgbase-$pkgver"
  patch -p1 -i "$srcdir/Makefile.patch"
  sed -i '
    /docbook\.xsl/ s@/stylesheet/nwalsh/@/'"$(
      ls /usr/share/xml/docbook/ \
      | grep -wF xsl-stylesheets \
      | grep -vwF nons \
      | sort -V \
      | tail -n1
    )"'/@
  ' Makefile
}

build() {
  cd "$srcdir/$pkgbase-$pkgver"
  make all doc
  find . -type f \( -name '*.8' -o -name '*.8mandos' -o -name '*.5' \) -exec sed -i 's@^\s\+@@' {} +
}

_package() {
  cd "$srcdir/$pkgbase-$pkgver"
  make install-$1 DESTDIR="$pkgdir" BINDIR="$pkgdir/usr/bin"
}

package_mandos-server() {
  arch=(any)
  _pinned_dependencies=(
  )
  _package server
}

package_mandos-client-nokey() {
  _pinned_dependencies=(
    'gcc-libs=14.2.1+r134+gab884fffe3fc'
    'glibc>=2.38'
    'gnutls=3.8.7'
    'libavahi-common.so=3'
    'libavahi-core.so=7'
    'libglib-2.0.so=0'
    'libgpgme.so=11'
    'libnl-3.so=200'
    'libnl-route-3.so=200'
  )
  depends+=("${_pinned_dependencies[@]}")
  _package client-nokey
}