# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Kyle Keen <keenerd@gmail.com>
pkgname=hyperrogue
pkgver=12.1q
pkgrel=9
pkgdesc="You are a lone outsider in a strange, non-Euclidean hyperbolic world.  Optional music."
arch=('i686' 'pentium4' 'x86_64')
url="http://www.roguetemple.com/z/hyper.php"
license=('GPL2')
_pinned_dependencies=(
  'gcc-libs=13.2.1'
  'glibc>=2.31'
  'libGL.so=1'
  'libz.so=1'
  'sdl12-compat=1.2.68'
  'sdl_gfx=2.0.27'
)
depends=('sdl_ttf' 'sdl_mixer' 'mesa' 'ttf-dejavu' "${_pinned_dependencies[@]}")
makedepends=('glu')

source=("https://github.com/zenorogue/hyperrogue/archive/refs/tags/v${pkgver}.tar.gz")
sha512sums=('ca3ada6d145b01a0b6ab61c4142c761ae1c89f43903d4054551199f28ff2a738c811024b6ffb5cace8a03b6d52c4761d96a6b3b756c7d8ddaeb1493f0787c247')

prepare() {
    cd "$srcdir/$pkgname-${pkgver}"
    sed -i 's|TTF_OpenFont.*;|TTF_OpenFont("/usr/share/fonts/TTF/DejaVuSans-Bold.ttf", siz);|' basegraph.cpp
    #sed -i 's|<SDL.h>|"SDL.h"|' /usr/include/SDL/SDL_gfxPrimitives.h  # todo: confirm bug and open
    sed -i 's|-c hyper.cpp|& -I/usr/include/SDL/|' Makefile  # remove when above bug is fixed
    sed -i 's|savepng.c|savepng.cpp|' Makefile
    sed -i 's|-Werror||' Makefile
}

build() {
    cd "$srcdir/$pkgname-${pkgver}"
    make
}

package() {
    cd "$srcdir/$pkgname-${pkgver}"
    install -Dm755 hyperrogue "$pkgdir/usr/bin/hyperrogue"
}