# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Kyle Keen <keenerd@gmail.com>
pkgname=hyperrogue
pkgver=13.0t
pkgrel=2
pkgdesc="You are a lone outsider in a strange, non-Euclidean hyperbolic world.  Optional music."
arch=('i686' 'pentium4' 'x86_64')
url="http://www.roguetemple.com/z/hyper.php"
license=('GPL2')
_pinned_dependencies=(
  'gcc-libs=14.2.1+r26+g14fa2b2ae7f'
  'glibc>=2.31'
  'libglvnd=1.7.0'
  'sdl12-compat=1.2.68'
  'sdl_gfx=2.0.27'
  'zlib=1:1.3.1'
)
depends=('sdl_ttf' 'sdl_mixer' 'mesa' 'ttf-dejavu' "${_pinned_dependencies[@]}")
makedepends=('glu')

source=("https://github.com/zenorogue/hyperrogue/archive/refs/tags/v${pkgver}.tar.gz")
sha512sums=('61787c3b2ee40da0d01ac0377b070dee3d28f38c37f63e4407166f68c3618988d514b851df158dfb26a933d763b79d09dd8b1bd88931c943ff73657aad5f3f50')

prepare() {
    cd "$srcdir/$pkgname-${pkgver}"
    sed -i 's|TTF_OpenFont.*;|TTF_OpenFont("/usr/share/fonts/TTF/DejaVuSans-Bold.ttf", siz);|' basegraph.cpp
    #sed -i 's|<SDL.h>|"SDL.h"|' /usr/include/SDL/SDL_gfxPrimitives.h  # todo: confirm bug and open
    sed -i 's|-c hyper.cpp|& -I/usr/include/SDL/|' Makefile  # remove when above bug is fixed
    sed -i 's|savepng.c|savepng.cpp|' Makefile
    sed -i 's|-Werror||' Makefile
}

build() {
    cd "$srcdir/$pkgname-${pkgver}"
    make
}

package() {
    cd "$srcdir/$pkgname-${pkgver}"
    install -Dm755 hyperrogue "$pkgdir/usr/bin/hyperrogue"
}