# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Adrian C. <anrxc..sysphere.org>

pkgname=alpine
pkgver=2.26.r30.fb3f153
_commit=${pkgver##*.}
pkgrel=3
arch=("i686" "pentium4" "x86_64")
pkgdesc="Apache licensed PINE mail user agent"
url="http://alpine.freeiz.com"
license=("APACHE")
_pinned_dependencies=(
  'gcc-libs=14.1.1+r309+gbb34b7eda1f'
  'glibc>=2.31'
  'libcrypto.so=3'
  'libcrypt.so=2'
  'libgssapi_krb5.so=2'
  'libkrb5.so=3'
  'libldap=2.6.8'
  'libncursesw.so=6'
  'libssl.so=3'
)
depends=("gettext" "${_pinned_dependencies[@]}")
makedepends=('openssl' 'git')
optdepends=("aspell: for spell-checking support"
            "hunspell: for spell-checking support")
provides=("pine")
conflicts=("pine" "re-alpine")
replaces=("pine")
options=("!makeflags")
source=(
  "alpine::git://repo.or.cz/alpine.git#commit=${_commit}"
  'default-pipe.patch'
  'rules.patch'
)
sha512sums=('d70d3b5d3514907936bc81710c6684e3f4764af551ad81ea40cd496aea7537db558c3790c72b8eda8a021adec286a1d681007692570aa0681067a3f5603bc02e'
            '15f2143d7fd33b16eedac778aebcff8b89a2c6fdad65e100ad643f397f3d85207c66325975ad73f5189c187d8420f5e7c811e54257c67f97ee69b2ccf50d63e2'
            '65b6505e5842cc3d09ad6c38c79ed308d42e07c12d736e3531e9887adc3b75bdb7d3be2bff0c1f4d42c00ce4a861649d76d7f43cc428e836720c03d5aa650e9f')

prepare() {
  cd "${srcdir}/${pkgname}"
  patch -p1 -i "${srcdir}/default-pipe.patch"
  patch -p1 -i "${srcdir}/rules.patch"
}

pkgver() {
  cd "${srcdir}/${pkgname}"
  _rev=$(
    git rev-parse --short "${_commit}"
  )
  _pkgver=$(
    git archive "${_rev}" -- configure | \
      tar -Ox | \
      sed -n '
        /^\s*VERSION\s*=/!d
        =
        s/^.*=\s*//
        s/['"'"'"]//g
        p
        q
      ' | \
      sed '
        N
        s/\n/ /
      '
  )
  _line=${_pkgver% *}
  _pkgver=${_pkgver#* }
  _rev_count=$(
    git rev-list "${_rev}" ^$(git blame -L${_line},${_line} "${_rev}" -- configure | cut -d' ' -f1) --count
  )
  printf '%s.r%s.%s' \
    "${_pkgver}" \
    "${_rev_count}" \
    "${_rev}"
}

build() {
  cd "${srcdir}/${pkgname}"

# Configure Alpine
  ./configure --prefix=/usr \
  --with-passfile=.pine-passfile \
  --without-tcl \
  --with-system-pinerc=/etc/${pkgname}.d/pine.conf \
  --with-system-fixed-pinerc=/etc/${pkgname}.d/pine.conf.fixed

# Build Alpine
  make
}

package() {
  cd "${srcdir}/${pkgname}"

# Install Alpine
  make DESTDIR="${pkgdir}" install
}