openlens-bin new

1 files changed, 82 insertions, 0 deletions

diff --git a/openlens-bin/PKGBUILD b/openlens-bin/PKGBUILD
new file mode 100644
index 000000000..5b8cc420c
--- /dev/null
+++ b/openlens-bin/PKGBUILD
@@ -0,0 +1,82 @@
+# Maintainer: Erich Eckner <arch at eckner dot net>
+# Contributor: beliys <aur at bil dot co dot ua>
+# based on lens-bin
+
+_pkgname=OpenLens
+pkgname=openlens-bin
+pkgver=6.5.2
+pkgrel=1
+pkgdesc='The Kubernetes IDE (fork lens-bin without lenscloud-lens-extension). Read more - https://github.com/lensapp/lens/issues/5444'
+arch=('x86_64' 'aarch64')
+license=('MIT')
+url='https://k8slens.dev'
+_pinned_dependencies=(
+  'gcc-libs=13.1.1'
+  'glibc>=2.37'
+  'libatk-1.0.so=0'
+  'libatk-bridge-2.0.so=0'
+  'libatspi.so=0'
+  'libcairo.so=2'
+  'libcups=1:2.4.6'
+  'libdbus-1.so=3'
+  'libdrm=2.4.115'
+  'libexpat.so=1'
+  'libgio-2.0.so=0'
+  'libglib-2.0.so=0'
+  'libgobject-2.0.so=0'
+  'libgtk-3.so=0'
+  'libpango-1.0.so=0'
+  'libx11=1.8.6'
+  'libxcb=1.15'
+  'libxcomposite=0.4.6'
+  'libxdamage=1.1.6'
+  'libxext=1.3.5'
+  'libxfixes=6.0.1'
+  'libxkbcommon.so=0'
+  'libxrandr=1.5.3'
+  'mesa=23.1.3'
+  'nspr=4.35'
+  'nss=3.91'
+)
+depends=('gtk3' 'libxss' 'nss' "${_pinned_dependencies[@]}")
+provides=('lens')
+conflicts=('lens' 'lens-bin')
+source=("${_pkgname}.desktop")
+source_x86_64=(${_pkgname}-${pkgver}-x86_64.AppImage::"https://github.com/beliys/OpenLens/releases/download/v${pkgver}/${_pkgname}-${pkgver}.x86_64.AppImage")
+source_aarch64=(${_pkgname}-${pkgver}-aarch64.AppImage::"https://github.com/beliys/OpenLens/releases/download/v${pkgver}/${_pkgname}-${pkgver}.arm64.AppImage")
+sha256sums=('30ab2e9f91ca6be993b5893fb385a225c6d06f6d11caa305e0d109348b5d132c')
+sha256sums_x86_64=('de16abbd390d9196be8a89c6d8cb29184bb05bca2626b7e8cfd502d8fbdc8e40')
+sha256sums_aarch64=('19f30368b31a5352f8fc6e1d25a78ba7d54102867bd062992c80d10ea4308082')
+
+prepare() {
+  chmod +x "${_pkgname}-${pkgver}-${CARCH}.AppImage"
+  "./${_pkgname}-${pkgver}-${CARCH}.AppImage" --appimage-extract
+}
+
+package() {
+  # move the entire distribution to /usr/share
+  mkdir -p "${pkgdir}"/usr/share/${_pkgname}
+  mv "${srcdir}"/squashfs-root/* \
+    "${pkgdir}"/usr/share/${_pkgname}
+
+  # icon
+  install -Dm 644 "${pkgdir}"/usr/share/${_pkgname}/usr/share/icons/hicolor/512x512/apps/open-lens.png \
+    "${pkgdir}"/usr/share/icons/hicolor/512x512/apps/open-lens.png
+
+  # desktop file
+  install -Dm 644 "${srcdir}"/${_pkgname}.desktop \
+    "${pkgdir}"/usr/share/applications/${_pkgname}.desktop
+
+  # symlink binary
+  mkdir -p "${pkgdir}"/usr/bin
+  ln -sf /usr/share/${_pkgname}/open-lens \
+    "${pkgdir}"/usr/bin/open-lens
+
+  # clean and fix permissions
+  find "${pkgdir}" -type d -exec chmod 755 {} \;
+  chmod -x "${pkgdir}"/usr/share/${_pkgname}/*.so
+  rm -rf "${pkgdir}"/usr/share/${_pkgname}/AppRun
+  rm -rf "${pkgdir}"/usr/share/${_pkgname}/lens.{desktop,png}
+  rm -rf "${pkgdir}"/usr/share/${_pkgname}/usr
+  rm -rf "${pkgdir}"/usr/share/${_pkgname}/resources/extensions/*/dist/*-arm64
+}