mise new

1 files changed, 52 insertions, 0 deletions

diff --git a/mise/PKGBUILD b/mise/PKGBUILD
new file mode 100644
index 000000000..46446c120
--- /dev/null
+++ b/mise/PKGBUILD
@@ -0,0 +1,52 @@
+# Maintainer: Erich Eckner <arch at eckner dot net>
+# Contributor: Jeff Dickey <releases at mise dot jdx dot dev>
+
+pkgname=mise
+pkgver=2024.6.4
+pkgrel=1
+pkgdesc='The front-end to your dev env'
+arch=('x86_64')
+url='https://github.com/jdx/mise'
+license=('MIT')
+makedepends=('cargo')
+provides=('mise')
+conflicts=('rtx' 'rtx-bin')
+replaces=('rtx')
+options=('!lto')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/jdx/$pkgname/archive/v$pkgver.tar.gz")
+sha512sums=('dd994d482da87fb380d9cf6618e8a05c2aebcb7b695cdddebfc1e6404ba04aee8416e8acad31d1a49f894ad3cdffb6f5018997eea5a8bd98cc7b2eb2f10b2991')
+optdepends=('usage: completion support')
+_pinned_dependencies=(
+  'gcc-libs=14.1.1+r58+gfc9fb69ad62'
+  'glibc>=2.39+r52+gf8e4623421'
+  'libcrypto.so=3'
+  'libssl.so=3'
+  'libz.so=1'
+)
+depends=("${_pinned_dependencies[@]}")
+
+prepare() {
+  cd "$srcdir/$pkgname-$pkgver"
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+  export RUSTUP_TOOLCHAIN=stable
+  export CARGO_TARGET_DIR=target
+  cargo build --frozen --release
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+  install -Dm755 target/release/mise "$pkgdir/usr/bin/mise"
+  install -Dm644 man/man1/mise.1 "$pkgdir/usr/share/man/man1/mise.1"
+  install -Dm644 completions/mise.bash "$pkgdir/usr/share/bash-completion/completions/mise"
+  install -Dm644 completions/mise.fish "$pkgdir/usr/share/fish/completions/mise.fish"
+  install -Dm644 completions/_mise "$pkgdir/usr/share/zsh/site-functions/_mise"
+}
+
+check() {
+  cd "$srcdir/$pkgname-$pkgver"
+  ./target/release/mise --version
+}