# Maintainer: Erich Eckner <arch at eckner dot net>
pkgbase=simple-pki
pkgdesc='Scripts to manage a simple pki'
pkgname=(simple-pki-ca simple-pki-cb)
pkgver=0.3.1
pkgrel=1
arch=('any')
url="https://git.eckner.net/Erich/${pkgname}"
license=('GPL')
makedepends=('nginx' 'openssl' 'rsync')
source=(
    "https://git.eckner.net/Erich/${pkgbase}/snapshot/${pkgbase}-${pkgver}.tar.xz"
)
sha512sums=('67f6cc8367687e38a23fbd7196ee5562b7fa6982796842c9c581c9e2f9cd62bd6d972e2a0d6ffba715231f92367d0cc072432a9c98017ced7bbe04b26b64aa72')

build() {

  cd ${pkgbase}-${pkgver}
  make

}

package_simple-pki-ca() {

  backup=(
    "etc/${pkgbase}/ca.conf"
    "etc/${pkgbase}/ca-ssl.conf"
  )
  pkgdesc="Scripts to manage a simple pki ca - including automatic renewal"
  depends=('openssl' 'rsync')

  cd ${pkgbase}-${pkgver}
  make DESTDIR=${pkgdir} install-ca

}

package_simple-pki-cb() {

  backup=(
    "etc/${pkgbase}/cb.conf"
    "etc/${pkgbase}/server-ssl.conf"
  )
  pkgdesc="Scripts to manage simple pki clients - including automatic renewal"
  depends=('openssl' 'nginx')

  cd ${pkgbase}-${pkgver}
  make DESTDIR=${pkgdir} install-cb

}