# Maintainer: Erich Eckner <arch at eckner dot net>
pkgname=python-pymca
_pkgname="${pkgname#*-}"
pkgver=5.6.3
pkgrel=2
pkgdesc='Stand-alone application and Python tools for interactive and/or batch processing analysis of X-Ray Fluorescence Spectra'
arch=('i686' 'pentium4' 'x86_64')
url='http://pymca.sourceforge.net/index.html'
license=('MIT License')
_pinned_dependencies=(
  'glibc>=2.31'
)
makedepends=(
  'python-numpy'
  'python-setuptools')
depends=(
  'python>=3.9'
  'python<3.10'
  'python-numpy')
optdepends=(
  'python-pyqt5: gui'
  'python-matplotlib: gui')
source=(
    "${_pkgname}-v${pkgver}.tar.gz::https://github.com/vasole/${_pkgname}/archive/v${pkgver}.tar.gz"
)
sha512sums=('01cf64518601f63ad8f3f4a519058ebfc8c1dc70865c7a0a874451ef89583b239446656e3e8419836379e02ec7661e05af31f851797cf694dac4183b65ec6636')

build() {
  cd ${_pkgname}-${pkgver}
  python setup.py build
}

package() {
  cd ${_pkgname}-${pkgver}
  python setup.py install --skip-build --root="${pkgdir}" --prefix=/usr
}