# Contributor: Francois Boulogne <fboulogne at april dot org>
# Maintainer: Erich Eckner <arch at eckner dot net>

pkgname='python-lmfit'
_pkgname=lmfit-py
pkgver=1.0.0
pkgrel=2
pkgdesc="Least-Squares Minimization with Constraints for Python"
arch=('any')
url="http://lmfit.github.io/lmfit-py/"
license=('BSD')
depends=(
  'python>=3.8'
  'python<3.9'
  'python-asteval>=0.9.16'
  'python-numpy>=1.16'
  'python-scipy>=1.2'
  'python-uncertainties>=3.0.1')
makedepends=(
  'python-setuptools')
checkdepends=(
  'python-nose')
source=("${_pkgname}-${pkgver}.tar.gz::https://github.com/lmfit/lmfit-py/archive/${pkgver}.tar.gz")
sha512sums=('48c8785c23b8f398e8d01876d917ee3fefe9a429fc6f5238caa7fd0ccea5f0bf35f685572695e53f31389926fb4e44df2701d3423f4f867c6351177c8ce327a0')

build() {
  cd "$srcdir/lmfit-py-$pkgver"
  python setup.py build
}

check() {
  cd "$srcdir/lmfit-py-$pkgver"
  nosetests3 tests || echo 'WARNING: python3 tests failed'
}

package(){
  cd "$srcdir/lmfit-py-$pkgver"
  python setup.py install --root="$pkgdir/" --optimize=1
}